dnl Process this file with autoconf to produce a configure script.
AC_INIT(src/)

PACKAGE=swftools
VERSION=0.4.2
# -Winline?
CFLAGS="-Wparentheses -Wimplicit -Wreturn-type -O2 -fomit-frame-pointer"
CXXFLAGS="-Wparentheses -Wimplicit -Wreturn-type -O2 -fomit-frame-pointer"
export PACKAGE VERSION CFLAGS CXXFLAGS

dnl Checks for programs.
 AC_PROG_CC
 AC_PROG_CPP
 AC_PROG_CXX
 AC_PROG_RANLIB
 AC_PROG_MAKE_SET
 AC_PROG_INSTALL
 AC_PROG_LN_S
 AC_PROG_LIBTOOL
 AC_CHECK_PROGS(UNCOMPRESS, gzip uncompress compress, )

dnl Checks for system services
 AC_EXEEXT

dnl Checks for libraries.
 AC_CHECK_LIB(m, sin,, 
 echo "Error: Math library not found.";
 exit;
 )
 AC_CHECK_LIB(z, deflate,, 
 echo "Error: The zlib compression library is required."
 DISABLEPDF2SWF=true; 
 MISSINGLIBS="${MISSINGLIBS} zlib"
 exit;
 )
 AC_CHECK_LIB(jpeg, jpeg_write_raw_data,, 
 DISABLEPDF2SWF=true;
 DISABLEJPEG2SWF=true;
 MISSINGLIBS="${MISSINGLIBS} jpeglib"
 )
 AC_CHECK_LIB(t1, T1_LoadFont,,
 DISABLEPDF2SWF=true;
 MISSINGLIBS="${MISSINGLIBS} T1lib"
 )

RFX_CHECK_BYTEORDER
AC_SUBST(WORDS_BIGENDIAN)
RFX_CHECK_SYSTEM_BACKTICKS
AC_SUBST(SYSTEM_BACKTICKS)

AC_ARG_PROGRAM

dnl do we need those?
dnl AC_CHECK_LIB(pthread, pthread_create)
dnl AC_CHECK_LIB(X11, XFlush)

dnl Checks for header files.
 AC_CONFIG_HEADER(config.h)
dnl AC_PATH_X
dnl AC_PATH_XTRA
 AC_HEADER_DIRENT
 AC_HEADER_STDC
 AC_CHECK_HEADERS(zlib.h jpeglib.h t1lib.h sys/stat.h sys/types.h dirent.h sys/bsdtypes.h sys/ndir.h sys/dir.h ndir.h)

if test "x${ac_cv_header_jpeglib_h}" != "xyes"; then
 DISABLEPDF2SWF=true;
 DISABLEJPEG2SWF=true;
 MISSINGLIBS="${MISSINGLIBS} jpeglib.h"
fi
if test "x${ac_cv_header_t1lib_h}" != "xyes"; then
 DISABLEPDF2SWF=true;
 MISSINGLIBS="${MISSINGLIBS} t1lib.h"
fi
if test "x${ac_cv_header_zlib_h}" != "xyes"; then
 DISABLEPDF2SWF=true;
 MISSINGLIBS="${MISSINGLIBS} zlib.h"
fi

AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
AC_SUBST(PACKAGE)
AC_SUBST(VERSION)

AC_SUBST(HAVE_UNISTD_H)
AC_SUBST(EXEEXT)

dnl Checks for typedefs, structures, and compiler characteristics.
 AC_C_CONST
 AC_C_INLINE
 AC_TYPE_OFF_T
 AC_TYPE_SIZE_T
 AC_STRUCT_TM
 AC_CHECK_TYPE(boolean,int)
 AC_CHECK_TYPE(bool,char)
 dnl AC_CHECK_TYPE(uchar,unsigned char)
 dnl AC_CHECK_TYPE(schar,signed char)
 dnl AC_CHECK_TYPE(word,unsigned short int)
 dnl AC_CHECK_TYPE(sword,unsigned short int)
 dnl AC_CHECK_TYPE(uint,unsigned long int)

dnl Checks for library functions.
 AC_CHECK_FUNCS(popen mkstemp stat lrand48 rand srand48 srand)
 RFX_CHECK_AVI2SWF

avi2swf="avi2swf/Makefile"
if test "x${AVIFILE}" != "xtrue"; then
 echo "* Couldn't compile the avifile test program."
 echo "* Disabling avi2swf tool..."
 echo all: > avi2swf/Makefile
 echo install: >> avi2swf/Makefile
 echo clean: >> avi2swf/Makefile
 avi2swf=
fi

if test "x${UNCOMPRESS}" = "xgzip"; then
    AC_DEFINE_UNQUOTED(USE_GZIP, 1)
fi
AC_SUBST(USE_GZIP)

JPEG2SWF='jpeg2swf$(EXEEXT)'
export JPEG2SWF
if test "x${DISABLEPDF2SWF}" = "xtrue"; then
  echo "***************************************************"
  echo "The following headers/libraries are missing: " ${MISSINGLIBS}
  echo "Disabling pdf2swf tool..."
  rm -f pdf2swf/Makefile
  echo all: > pdf2swf/Makefile
  echo install: >> pdf2swf/Makefile
  echo clean: >> pdf2swf/Makefile
  if test "x${DISABLEJPEG2SWF}" = "xtrue"; then
    echo "Disabling jpeg2swf tool..."
    JPEG2SWF=
    export JPEG2SWF
  fi
  echo "***************************************************"
  FILES="./release ${avi2swf} Makefile lib/lame/Makefile lib/Makefile src/Makefile swfs/Makefile"
else
  FILES="./release ${avi2swf} Makefile lib/lame/Makefile lib/Makefile src/Makefile pdf2swf/Makefile pdf2swf/xpdf/Makefile pdf2swf/ttf2pt1/Makefile pdf2swf/fonts/Makefile swfs/Makefile"
fi
AC_SUBST(JPEG2SWF)

AC_OUTPUT(${FILES})