lib/as3/tokenizer.lex

   1 /* tokenizer.lex
   2
   3    Routines for compiling Flash2 AVM2 ABC Actionscript
   4
   5    Extension module for the rfxswf library.
   6    Part of the swftools package.
   7
   8    Copyright (c) 2008 Matthias Kramm <kramm@quiss.org>
   9
  10    This program is free software; you can redistribute it and/or modify
  11    it under the terms of the GNU General Public License as published by
  12    the Free Software Foundation; either version 2 of the License, or
  13    (at your option) any later version.
  14
  15    This program is distributed in the hope that it will be useful,
  16    but WITHOUT ANY WARRANTY; without even the implied warranty of
  17    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18    GNU General Public License for more details.
  19
  20    You should have received a copy of the GNU General Public License
  21    along with this program; if not, write to the Free Software
  22    Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA */
  23 %{
  24
  25
  26 #include <string.h>
  27 #include <stdlib.h>
  28 #include <stdio.h>
  29 #include <stdarg.h>
  30 #include "../utf8.h"
  31 #include "common.h"
  32 #include "tokenizer.h"
  33 #include "files.h"
  34
  35 unsigned int as3_tokencount = 0;
  36
  37 static void dbg(const char*format, ...)
  38 {
  39     char buf[1024];
  40     int l;
  41     va_list arglist;
  42     if(as3_verbosity<3)
  43         return;
  44     va_start(arglist, format);
  45     vsnprintf(buf, sizeof(buf)-1, format, arglist);
  46     va_end(arglist);
  47     l = strlen(buf);
  48     while(l && buf[l-1]=='\n') {
  49         buf[l-1] = 0;
  50         l--;
  51     }
  52     printf("(tokenizer) ");
  53     printf("%s\n", buf);
  54     fflush(stdout);
  55 }
  56
  57 #ifndef YY_CURRENT_BUFFER
  58 #define YY_CURRENT_BUFFER yy_current_buffer
  59 #endif
  60
  61 static void*as3_buffer=0;
  62 static int as3_buffer_pos=0;
  63 static int as3_buffer_len=0;
  64 void as3_file_input(FILE*fi)
  65 {
  66     as3_in = fi;
  67     as3_buffer = 0;
  68 }
  69 void as3_buffer_input(void*buffer, int len)
  70 {
  71     if(!buffer)
  72         syntaxerror("trying to parse zero bytearray");
  73     as3_buffer = buffer;
  74     as3_buffer_len = len;
  75     as3_buffer_pos = 0;
  76     as3_in = 0;
  77 }
  78
  79 #define YY_INPUT(buf,result,max_size) { \
  80   if(!as3_buffer) { \
  81       errno=0; \
  82       while((result = fread(buf, 1, max_size, as3_in))==0 && ferror(as3_in)) \
  83       { if(errno != EINTR) {YY_FATAL_ERROR("input in flex scanner failed"); break;} \
  84         errno=0; clearerr(as3_in); \
  85       } \
  86   } else { \
  87       int to_read = max_size; \
  88       if(to_read + as3_buffer_pos > as3_buffer_len) \
  89           to_read = as3_buffer_len - as3_buffer_pos; \
  90       memcpy(buf, as3_buffer+as3_buffer_pos, to_read); \
  91       as3_buffer_pos += to_read; \
  92       result=to_read; \
  93   } \
  94 }
  95
  96 void handleInclude(char*text, int len, char quotes)
  97 {
  98     char*filename = 0;
  99     if(quotes) {
 100         char*p1 = strchr(text, '"');
 101         char*p2 = strrchr(text, '"');
 102         if(!p1 || !p2 || p1==p2) {
 103             syntaxerror("Invalid include in line %d\n", current_line);
 104         }
 105         *p2 = 0;
 106         filename = strdup(p1+1);
 107     } else {
 108         int i1=0,i2=len;
 109         // find start
 110         while(!strchr(" \n\r\t", text[i1])) i1++;
 111         // strip
 112         while(strchr(" \n\r\t", text[i1])) i1++;
 113         while(strchr(" \n\r\t", text[i2-1])) i2--;
 114         if(i2!=len) text[i2]=0;
 115         filename = strdup(&text[i1]);
 116     }
 117
 118     char*fullfilename = find_file(filename, 1);
 119     enter_file2(filename, fullfilename, YY_CURRENT_BUFFER);
 120     yyin = fopen(fullfilename, "rb");
 121     if (!yyin) {
 122         syntaxerror("Couldn't open include file \"%s\"\n", fullfilename);
 123     }
 124
 125     yy_switch_to_buffer(yy_create_buffer( yyin, YY_BUF_SIZE ) );
 126     //BEGIN(DEFAULT); keep context
 127 }
 128
 129 static int do_unescape(const char*s, const char*end, char*n)
 130 {
 131     char*o = n;
 132     int len=0;
 133     while(s<end) {
 134         if(*s!='\\') {
 135             if(o) o[len] = *s;len++;
 136             s++;
 137             continue;
 138         }
 139         s++; //skip past '\'
 140         if(s==end) syntaxerror("invalid \\ at end of string");
 141
 142         /* handle the various line endings (mac, dos, unix) */
 143         if(*s=='\r') {
 144             s++;
 145             if(s==end) break;
 146             if(*s=='\n')
 147                 s++;
 148             continue;
 149         }
 150         if(*s=='\n')  {
 151             s++;
 152             continue;
 153         }
 154         switch(*s) {
 155             case '\\': if(o) o[len] = '\\';s++;len++; break;
 156             case '"': if(o) o[len] = '"';s++;len++; break;
 157             case '\'': if(o) o[len] = '\'';s++;len++; break;
 158             case 'b': if(o) o[len] = '\b';s++;len++; break;
 159             case 'f': if(o) o[len] = '\f';s++;len++; break;
 160             case 'n': if(o) o[len] = '\n';s++;len++; break;
 161             case 'r': if(o) o[len] = '\r';s++;len++; break;
 162             case 't': if(o) o[len] = '\t';s++;len++; break;
 163             case '0': case '1': case '2': case '3': case '4': case '5': case '6': case '7': {
 164                 unsigned int num=0;
 165                 int nr = 0;
 166                 while(strchr("01234567", *s) && nr<3 && s<end) {
 167                     num <<= 3;
 168                     num |= *s-'0';
 169                     nr++;
 170                     s++;
 171                 }
 172                 if(num>256)
 173                     syntaxerror("octal number out of range (0-255): %d", num);
 174                 if(o) o[len] = num;len++;
 175                 continue;
 176             }
 177             case 'x': case 'u': {
 178                 int max=2;
 179                 char bracket = 0;
 180                 char unicode = 0;
 181                 if(*s == 'u') {
 182                     max = 6;
 183                     unicode = 1;
 184                 }
 185                 s++;
 186                 if(s==end) syntaxerror("invalid \\u or \\x at end of string");
 187                 if(*s == '{')  {
 188                     s++;
 189                     if(s==end) syntaxerror("invalid \\u{ at end of string");
 190                     bracket=1;
 191                 }
 192                 unsigned int num=0;
 193                 int nr = 0;
 194                 while(strchr("0123456789abcdefABCDEF", *s) && (bracket || nr < max) && s<end) {
 195                     num <<= 4;
 196                     if(*s>='0' && *s<='9') num |= *s - '0';
 197                     if(*s>='a' && *s<='f') num |= *s - 'a' + 10;
 198                     if(*s>='A' && *s<='F') num |= *s - 'A' + 10;
 199                     nr++;
 200                     s++;
 201                 }
 202                 if(bracket) {
 203                     if(*s=='}' && s<end) {
 204                         s++;
 205                     } else {
 206                         syntaxerror("missing terminating '}'");
 207                     }
 208                 }
 209                 if(unicode) {
 210                     char*utf8 = getUTF8(num);
 211                     while(*utf8) {
 212                         if(o) o[len] = *utf8;utf8++;len++;
 213                     }
 214                 } else {
 215                     if(num>256)
 216                         syntaxerror("byte out of range (0-255): %d", num);
 217                     if(o) o[len] = num;len++;
 218                 }
 219                 break;
 220             }
 221             default: {
 222                 if(o) {
 223                     o[len+0] = '\\';
 224                     o[len+1] = *s;
 225                 }
 226                 s++;
 227                 len+=2;
 228                 break;
 229             }
 230         }
 231     }
 232     if(o) o[len]=0;
 233     return len;
 234 }
 235
 236 static string_t string_unescape(const char*in, int l)
 237 {
 238     const char*s = in;
 239     const char*end = &in[l];
 240
 241     int len = do_unescape(s, end, 0);
 242     char*n = (char*)malloc(len+1);
 243     do_unescape(s, end, n);
 244     string_t out = string_new(n, len);
 245     return out;
 246 }
 247
 248 static void handleCData(char*s, int len)
 249 {
 250     a3_lval.str.str = s+9;    // <![CDATA[
 251     a3_lval.str.len = len-9-3;// ]]>
 252     a3_lval.str.str = strdup_n(a3_lval.str.str, a3_lval.str.len);
 253 }
 254
 255 static void handleRaw(char*s, int len)
 256 {
 257     a3_lval.str.len = len;
 258     a3_lval.str.str = strdup_n(s, a3_lval.str.len);
 259 }
 260
 261 static void handleString(char*s, int len)
 262 {
 263     if(s[0]=='"') {
 264         if(s[len-1]!='"') syntaxerror("String doesn't end with '\"'");
 265         s++;len-=2;
 266     }
 267     else if(s[0]=='\'') {
 268         if(s[len-1]!='\'') syntaxerror("String doesn't end with '\"'");
 269         s++;len-=2;
 270     }
 271     else syntaxerror("String incorrectly terminated");
 272
 273     a3_lval.str = string_unescape(s, len);
 274 }
 275
 276
 277 char start_of_expression;
 278
 279 static inline int m(int type)
 280 {
 281     a3_lval.token = type;
 282     return type;
 283 }
 284
 285 static char numberbuf[64];
 286 static char*nrbuf()
 287 {
 288     if(yyleng>sizeof(numberbuf)-1)
 289         syntaxerror("decimal number overflow");
 290     char*s = numberbuf;
 291     memcpy(s, yytext, yyleng);
 292     s[yyleng]=0;
 293     return s;
 294 }
 295
 296 static inline int setint(int v)
 297 {
 298     a3_lval.number_int = v;
 299     return T_INT;
 300 }
 301 static inline int setfloat(double v)
 302 {
 303     a3_lval.number_float = v;
 304     return T_FLOAT;
 305 }
 306
 307 static inline int handlefloat()
 308 {
 309     char*s = nrbuf();
 310     a3_lval.number_float = atof(s);
 311     return T_FLOAT;
 312 }
 313
 314 static inline int handleint()
 315 {
 316     char*s = nrbuf();
 317     char l = (yytext[0]=='-');
 318
 319     //char*max = l?"1073741824":"2147483647";
 320     char*max = l?"2147483648":"2147483647";
 321
 322     if(yyleng-l>10) {
 323         as3_softwarning("integer overflow: %s (converted to Number)", s);
 324         return handlefloat();
 325     }
 326     if(yyleng-l==10) {
 327         int t;
 328         for(t=0;t<yyleng-l;t++) {
 329             if(yytext[l+t]>max[t]) {
 330                 as3_softwarning("integer overflow: %s (converted to Number)", s);
 331                 return handlefloat();
 332             }
 333             else if(yytext[l+t]<max[t])
 334                 break;
 335         }
 336     }
 337     if(yytext[0]=='-') {
 338         int v = atoi(s);
 339         return setint(v);
 340     } else {
 341         unsigned int v = 0;
 342         int t;
 343         for(t=0;t<yyleng;t++) {
 344             v*=10;
 345             v+=yytext[t]-'0';
 346         }
 347         return setint(v);
 348     }
 349 }
 350
 351 static inline int handlehexfloat()
 352 {
 353     char l = (yytext[0]=='-')+2;
 354     double d=0;
 355     char dot=0;
 356     double base=1;
 357     int t;
 358     for(t=l;t<yyleng;t++) {
 359         char c = yytext[t];
 360         if(c=='.') {
 361             dot=1;
 362             continue;
 363         }
 364         if(!dot) {
 365             d*=16;
 366         } else {
 367             base*=1/16.0;
 368         }
 369         if(c>='0' && c<='9')
 370             d+=(c&15)*base;
 371         else if((c>='a' && c<='f') || (c>='A' && c<='F'))
 372             d+=((c&0x0f)+9)*base;
 373     }
 374     return setfloat(d);
 375 }
 376 static inline int handlehex()
 377 {
 378     char l = (yytext[0]=='-')+2;
 379     int len = yyleng;
 380
 381     if(len-l>8) {
 382         char*s = nrbuf();
 383         syntaxerror("integer overflow %s", s);
 384     }
 385
 386     int t;
 387     unsigned int v = 0;
 388     for(t=l;t<len;t++) {
 389         v<<=4;
 390         char c = yytext[t];
 391         if(c>='0' && c<='9')
 392             v|=(c&15);
 393         else if((c>='a' && c<='f') || (c>='A' && c<='F'))
 394             v|=(c&0x0f)+9;
 395     }
 396     if(l && v>=0x80000000) {
 397         char*s = nrbuf();
 398         as3_softwarning("integer overflow: %s (converted to Number)", s);
 399         return setfloat(v);
 400     }
 401     if(!l && v>0x7fffffff) {
 402         char*s = nrbuf();
 403         as3_softwarning("integer overflow: %s (converted to Number)", s);
 404         return setfloat(v);
 405     }
 406
 407     if(l==3) {
 408         return setint(-(int)v);
 409     } else {
 410         return setint(v);
 411     }
 412 }
 413
 414 void handleLabel(char*text, int len)
 415 {
 416     int t;
 417     for(t=len-1;t>=0;--t) {
 418         if(text[t]!=' ' &&
 419            text[t]!=':')
 420             break;
 421     }
 422     char*s = malloc(t+1);
 423     memcpy(s, yytext, t);
 424     s[t]=0;
 425     a3_lval.id = s;
 426 }
 427
 428 static int handleregexp()
 429 {
 430     char*s = malloc(yyleng);
 431     int len=yyleng-1;
 432     memcpy(s, yytext+1, len);
 433     s[len] = 0;
 434     int t;
 435     for(t=len;t>=0;--t) {
 436         if(s[t]=='/') {
 437             s[t] = 0;
 438             break;
 439         }
 440     }
 441     a3_lval.regexp.pattern = s;
 442     if(t==len) {
 443         a3_lval.regexp.options = 0;
 444     } else {
 445         a3_lval.regexp.options = s+t+1;
 446     }
 447     return T_REGEXP;
 448 }
 449
 450 void initialize_scanner();
 451 #define YY_USER_INIT initialize_scanner();
 452
 453 /* count the number of lines+columns consumed by this token */
 454 static inline void l() {
 455     int t;
 456     for(t=0;t<yyleng;t++) {
 457         if(yytext[t]=='\n') {
 458             current_line++;
 459             current_column=0;
 460         } else {
 461             current_column++;
 462         }
 463     }
 464 }
 465 /* count the number of columns consumed by this token */
 466 static inline void c() {
 467     current_column+=yyleng;
 468 }
 469
 470 trie_t*active_namespaces = 0;
 471 /*void tokenizer_register_namespace(const char*id)
 472 {
 473     trie_put(namespaces, id, 0);
 474 }
 475 void tokenizer_unregister_namespace(const char*id)
 476 {
 477     trie_remove(namespaces, id);
 478 }*/
 479 static inline char tokenizer_is_namespace(const char*id)
 480 {
 481     return trie_contains(active_namespaces, id);
 482 }
 483
 484 static inline int handleIdentifier()
 485 {
 486     char*s = malloc(yyleng+1);
 487     memcpy(s, yytext, yyleng);
 488     s[yyleng]=0;
 489     a3_lval.id = s;
 490     if(tokenizer_is_namespace(s))
 491         return T_NAMESPACE;
 492     else
 493         return T_IDENTIFIER;
 494 }
 495 static int tokenerror();
 496
 497
 498 //Boolean                      {c();return m(KW_BOOLEAN);}
 499 //int                          {c();return m(KW_INT);}
 500 //uint                         {c();return m(KW_UINT);}
 501 //Number                       {c();return m(KW_NUMBER);}
 502 //XMLCOMMENT  <!--([^->]|(-/[^-])|(--/[^>]))*-->
 503
 504 //{XMLCOMMENT}
 505 %}
 506
 507 %s REGEXPOK
 508 %s BEGINNING
 509 %s DEFAULT
 510 %x XMLTEXT
 511 %x XML
 512
 513 NAME     [a-zA-Z_][a-zA-Z0-9_\\]*
 514 _        [^a-zA-Z0-9_\\]
 515
 516 HEXINT    0x[a-zA-Z0-9]+
 517 HEXFLOAT  0x[a-zA-Z0-9]*\.[a-zA-Z0-9]*
 518 INT       [0-9]+
 519 FLOAT     ([0-9]+(\.[0-9]*)?|\.[0-9]+)(e[0-9]+)?
 520
 521 HEXWITHSIGN [+-]?({HEXINT})
 522 HEXFLOATWITHSIGN [+-]?({HEXFLOAT})
 523 INTWITHSIGN [+-]?({INT})
 524 FLOATWITHSIGN [+-]?({FLOAT})
 525
 526 CDATA       <!\[CDATA\[([^]]|\][^]]|\]\][^>])*\]*\]\]\>
 527 XMLCOMMENT  <!--([^->]|[-]+[^>-]|>)*-*-->
 528 XML         <[^>]+{S}>
 529
 530 STRING   ["](\\[\x00-\xff]|[^\\"\n])*["]|['](\\[\x00-\xff]|[^\\'\n])*[']
 531 S        [ \n\r\t]
 532 MULTILINE_COMMENT [/][*]+([*][^/]|[^/*]|[^*][/]|[\x00-\x1f])*[*]+[/]
 533 SINGLELINE_COMMENT \/\/[^\n\r]*[\n\r]
 534 REGEXP   [/]([^/\n]|\\[/])*[/][a-zA-Z]*
 535 %%
 536
 537
 538 {SINGLELINE_COMMENT}         {l(); /* single line comment */}
 539 {MULTILINE_COMMENT}          {l(); /* multi line comment */}
 540 [/][*]                       {syntaxerror("syntax error: unterminated comment", yytext);}
 541
 542 ^include{S}+{STRING}{S}*/\n    {l();handleInclude(yytext, yyleng, 1);}
 543 ^include{S}+[^" \t\r\n][\x20-\xff]*{S}*/\n    {l();handleInclude(yytext, yyleng, 0);}
 544 {STRING}                     {l(); BEGIN(DEFAULT);handleString(yytext, yyleng);return T_STRING;}
 545 {CDATA}                      {l(); BEGIN(DEFAULT);handleCData(yytext, yyleng);return T_STRING;}
 546
 547 <DEFAULT,BEGINNING,REGEXPOK>{
 548 {XMLCOMMENT}                 {l(); BEGIN(DEFAULT);handleRaw(yytext, yyleng);return T_STRING;}
 549 }
 550
 551 <XML>{
 552 {STRING}                     {l(); handleString(yytext, yyleng);return T_STRING;}
 553 [<]                          {c(); return m('<');}
 554 [/]                          {c(); return m('/');}
 555 [>]                          {c(); return m('>');}
 556 [=]                          {c(); return m('=');}
 557 {NAME}                       {c(); handleRaw(yytext, yyleng);return T_IDENTIFIER;}
 558 {S}                          {l();}
 559 <<EOF>>                      {syntaxerror("unexpected end of file");}
 560 }
 561
 562 <XMLTEXT>{
 563 [^<>]+                       {l(); BEGIN(DEFAULT);handleRaw(yytext, yyleng);return T_STRING;}
 564 [<]                          {c(); BEGIN(XML);return m('<');}
 565 [>]                          {c(); return m('>');}
 566 {XMLCOMMENT}                 {l(); handleRaw(yytext, yyleng);return T_STRING;}
 567 {CDATA}                      {l(); handleRaw(yytext, yyleng);return T_STRING;}
 568 <<EOF>>                      {syntaxerror("unexpected end of file");}
 569 }
 570
 571 <BEGINNING,REGEXPOK>{
 572 {REGEXP}                     {c(); BEGIN(DEFAULT);return handleregexp();}
 573 {HEXWITHSIGN}/{_}            {c(); BEGIN(DEFAULT);return handlehex();}
 574 {HEXFLOATWITHSIGN}/{_}       {c(); BEGIN(DEFAULT);return handlehexfloat();}
 575 {INTWITHSIGN}/{_}            {c(); BEGIN(DEFAULT);return handleint();}
 576 {FLOATWITHSIGN}/{_}          {c(); BEGIN(DEFAULT);return handlefloat();}
 577 }
 578
 579 <REGEXPOK>[\{]               {c(); BEGIN(REGEXPOK);return m(T_DICTSTART);}
 580 [\{]                         {c(); BEGIN(DEFAULT); return m('{');}
 581
 582 \xef\xbb\xbf                 {/* utf 8 bom */}
 583 {S}                          {l();}
 584
 585 {HEXINT}/{_}                 {c(); BEGIN(DEFAULT);return handlehex();}
 586 {HEXFLOAT}/{_}               {c(); BEGIN(DEFAULT);return handlehexfloat();}
 587 {INT}/{_}                    {c(); BEGIN(DEFAULT);return handleint();}
 588 {FLOAT}/{_}                  {c(); BEGIN(DEFAULT);return handlefloat();}
 589 NaN                          {c(); BEGIN(DEFAULT);return m(KW_NAN);}
 590
 591 3rr0r                        {/* for debugging: generates a tokenizer-level error */
 592                               syntaxerror("3rr0r");}
 593
 594 {NAME}{S}*:{S}*for/{_}       {l();BEGIN(DEFAULT);handleLabel(yytext, yyleng-3);return T_FOR;}
 595 {NAME}{S}*:{S}*do/{_}        {l();BEGIN(DEFAULT);handleLabel(yytext, yyleng-2);return T_DO;}
 596 {NAME}{S}*:{S}*while/{_}     {l();BEGIN(DEFAULT);handleLabel(yytext, yyleng-5);return T_WHILE;}
 597 {NAME}{S}*:{S}*switch/{_}    {l();BEGIN(DEFAULT);handleLabel(yytext, yyleng-6);return T_SWITCH;}
 598 for                          {c();BEGIN(DEFAULT);a3_lval.id="";return T_FOR;}
 599 do                           {c();BEGIN(DEFAULT);a3_lval.id="";return T_DO;}
 600 while                        {c();BEGIN(DEFAULT);a3_lval.id="";return T_WHILE;}
 601 switch                       {c();BEGIN(DEFAULT);a3_lval.id="";return T_SWITCH;}
 602
 603 [&][&]                       {c();BEGIN(REGEXPOK);return m(T_ANDAND);}
 604 [|][|]                       {c();BEGIN(REGEXPOK);return m(T_OROR);}
 605 [!][=]                       {c();BEGIN(REGEXPOK);return m(T_NE);}
 606 [!][=][=]                    {c();BEGIN(REGEXPOK);return m(T_NEE);}
 607 [=][=][=]                    {c();BEGIN(REGEXPOK);return m(T_EQEQEQ);}
 608 [=][=]                       {c();BEGIN(REGEXPOK);return m(T_EQEQ);}
 609 [>][=]                       {c();BEGIN(REGEXPOK);return m(T_GE);}
 610 [<][=]                       {c();BEGIN(REGEXPOK);return m(T_LE);}
 611 [-][-]                       {c();BEGIN(DEFAULT);return m(T_MINUSMINUS);}
 612 [+][+]                       {c();BEGIN(DEFAULT);return m(T_PLUSPLUS);}
 613 [+][=]                       {c();BEGIN(REGEXPOK);return m(T_PLUSBY);}
 614 [\^][=]                      {c();BEGIN(REGEXPOK);return m(T_XORBY);}
 615 [-][=]                       {c();BEGIN(REGEXPOK);return m(T_MINUSBY);}
 616 [/][=]                       {c();BEGIN(REGEXPOK);return m(T_DIVBY);}
 617 [%][=]                       {c();BEGIN(REGEXPOK);return m(T_MODBY);}
 618 [*][=]                       {c();BEGIN(REGEXPOK);return m(T_MULBY);}
 619 [|][=]                       {c();BEGIN(REGEXPOK);return m(T_ORBY);}
 620 [&][=]                       {c();BEGIN(REGEXPOK);return m(T_ANDBY);}
 621 [>][>][=]                    {c();BEGIN(REGEXPOK);return m(T_SHRBY);}
 622 [<][<][=]                    {c();BEGIN(REGEXPOK);return m(T_SHLBY);}
 623 [>][>][>][=]                 {c();BEGIN(REGEXPOK);return m(T_USHRBY);}
 624 [<][<]                       {c();BEGIN(REGEXPOK);return m(T_SHL);}
 625 [>][>][>]                    {c();BEGIN(REGEXPOK);return m(T_USHR);}
 626 [>][>]                       {c();BEGIN(REGEXPOK);return m(T_SHR);}
 627 \.\.\.                       {c();BEGIN(REGEXPOK);return m(T_DOTDOTDOT);}
 628 \.\.                         {c();BEGIN(REGEXPOK);return m(T_DOTDOT);}
 629 \.                           {c();BEGIN(REGEXPOK);return m('.');}
 630 ::                           {c();BEGIN(REGEXPOK);return m(T_COLONCOLON);}
 631 :                            {c();BEGIN(REGEXPOK);return m(':');}
 632 instanceof                   {c();BEGIN(REGEXPOK);return m(KW_INSTANCEOF);}
 633 implements                   {c();BEGIN(REGEXPOK);return m(KW_IMPLEMENTS);}
 634 interface                    {c();BEGIN(DEFAULT);return m(KW_INTERFACE);}
 635 namespace                    {c();BEGIN(DEFAULT);return m(KW_NAMESPACE);}
 636 protected                    {c();BEGIN(DEFAULT);return m(KW_PROTECTED);}
 637 undefined                    {c();BEGIN(DEFAULT);return m(KW_UNDEFINED);}
 638 continue                     {c();BEGIN(DEFAULT);return m(KW_CONTINUE);}
 639 override                     {c();BEGIN(DEFAULT);return m(KW_OVERRIDE);}
 640 internal                     {c();BEGIN(DEFAULT);return m(KW_INTERNAL);}
 641 function                     {c();BEGIN(DEFAULT);return m(KW_FUNCTION);}
 642 finally                      {c();BEGIN(DEFAULT);return m(KW_FINALLY);}
 643 default                      {c();BEGIN(DEFAULT);return m(KW_DEFAULT);}
 644 package                      {c();BEGIN(DEFAULT);return m(KW_PACKAGE);}
 645 private                      {c();BEGIN(DEFAULT);return m(KW_PRIVATE);}
 646 dynamic                      {c();BEGIN(DEFAULT);return m(KW_DYNAMIC);}
 647 extends                      {c();BEGIN(DEFAULT);return m(KW_EXTENDS);}
 648 delete                       {c();BEGIN(REGEXPOK);return m(KW_DELETE);}
 649 return                       {c();BEGIN(REGEXPOK);return m(KW_RETURN);}
 650 public                       {c();BEGIN(DEFAULT);return m(KW_PUBLIC);}
 651 native                       {c();BEGIN(DEFAULT);return m(KW_NATIVE);}
 652 static                       {c();BEGIN(DEFAULT);return m(KW_STATIC);}
 653 import                       {c();BEGIN(REGEXPOK);return m(KW_IMPORT);}
 654 typeof                       {c();BEGIN(REGEXPOK);return m(KW_TYPEOF);}
 655 throw                        {c();BEGIN(REGEXPOK);return m(KW_THROW);}
 656 class                        {c();BEGIN(DEFAULT);return m(KW_CLASS);}
 657 const                        {c();BEGIN(DEFAULT);return m(KW_CONST);}
 658 catch                        {c();BEGIN(DEFAULT);return m(KW_CATCH);}
 659 final                        {c();BEGIN(DEFAULT);return m(KW_FINAL);}
 660 false                        {c();BEGIN(DEFAULT);return m(KW_FALSE);}
 661 break                        {c();BEGIN(DEFAULT);return m(KW_BREAK);}
 662 super                        {c();BEGIN(DEFAULT);return m(KW_SUPER);}
 663 each                         {c();BEGIN(DEFAULT);return m(KW_EACH);}
 664 void                         {c();BEGIN(DEFAULT);return m(KW_VOID);}
 665 true                         {c();BEGIN(DEFAULT);return m(KW_TRUE);}
 666 null                         {c();BEGIN(DEFAULT);return m(KW_NULL);}
 667 else                         {c();BEGIN(DEFAULT);return m(KW_ELSE);}
 668 case                         {c();BEGIN(REGEXPOK);return m(KW_CASE);}
 669 with                         {c();BEGIN(REGEXPOK);return m(KW_WITH);}
 670 use                          {c();BEGIN(REGEXPOK);return m(KW_USE);}
 671 new                          {c();BEGIN(REGEXPOK);return m(KW_NEW);}
 672 get                          {c();BEGIN(DEFAULT);return m(KW_GET);}
 673 set                          {c();BEGIN(DEFAULT);return m(KW_SET);}
 674 var                          {c();BEGIN(DEFAULT);return m(KW_VAR);}
 675 try                          {c();BEGIN(DEFAULT);return m(KW_TRY);}
 676 is                           {c();BEGIN(REGEXPOK);return m(KW_IS) ;}
 677 in                           {c();BEGIN(REGEXPOK);return m(KW_IN) ;}
 678 if                           {c();BEGIN(DEFAULT);return m(KW_IF) ;}
 679 as                           {c();BEGIN(REGEXPOK);return m(KW_AS);}
 680 $?{NAME}                       {c();BEGIN(DEFAULT);return handleIdentifier();}
 681
 682 [\]\}*]                       {c();BEGIN(DEFAULT);return m(yytext[0]);}
 683 [+-\/^~@$!%&\(=\[|?:;,<>]   {c();BEGIN(REGEXPOK);return m(yytext[0]);}
 684 [\)\]]                           {c();BEGIN(DEFAULT);return m(yytext[0]);}
 685
 686 <DEFAULT,BEGINNING,REGEXPOK,XML,XMLTEXT>{
 687 .                            {tokenerror();}
 688 }
 689 <<EOF>>                      {l();
 690                               void*b = leave_file();
 691                               if (!b) {
 692                                  yyterminate();
 693                                  yy_delete_buffer(YY_CURRENT_BUFFER);
 694                                  return m(T_EOF);
 695                               } else {
 696                                   yy_delete_buffer(YY_CURRENT_BUFFER);
 697                                   yy_switch_to_buffer(b);
 698                               }
 699                              }
 700
 701 %%
 702
 703 int yywrap()
 704 {
 705     return 1;
 706 }
 707
 708 static int tokenerror()
 709 {
 710     char c1=yytext[0];
 711     char buf[128];
 712     buf[0] = yytext[0];
 713     int t;
 714     for(t=1;t<128;t++) {
 715         char c = buf[t]=input();
 716         if(c=='\n' || c==EOF)  {
 717             buf[t] = 0;
 718             break;
 719         }
 720     }
 721     if(c1>='0' && c1<='9')
 722         syntaxerror("syntax error: %s (identifiers must not start with a digit)");
 723     else
 724         syntaxerror("syntax error: %s", buf);
 725     printf("\n");
 726     exit(1);
 727     yyterminate();
 728 }
 729
 730
 731 static char mbuf[256];
 732 char*token2string(enum yytokentype nr, YYSTYPE v)
 733 {
 734     if(nr==T_STRING) {
 735         char*s = malloc(v.str.len+10);
 736         strcpy(s, "<string>");
 737         memcpy(s+8, v.str.str, v.str.len);
 738         sprintf(s+8+v.str.len, " (%d bytes)", v.str.len);
 739         return s;
 740     }
 741     else if(nr==T_REGEXP) {
 742         char*s = malloc(strlen(v.regexp.pattern)+10);
 743         sprintf(s, "<regexp>%s", v.regexp.pattern);
 744         return s;
 745     }
 746     else if(nr==T_IDENTIFIER) {
 747         char*s = malloc(strlen(v.id)+10);
 748         sprintf(s, "<ID>%s", v.id);
 749         return s;
 750     }
 751     else if(nr==T_INT)     return "<int>";
 752     else if(nr==T_UINT)     return "<uint>";
 753     else if(nr==T_FLOAT)     return "<float>";
 754     else if(nr==T_EOF)        return "***END***";
 755     else if(nr==T_GE)         return ">=";
 756     else if(nr==T_LE)         return "<=";
 757     else if(nr==T_MINUSMINUS) return "--";
 758     else if(nr==T_PLUSPLUS)   return "++";
 759     else if(nr==KW_IMPLEMENTS) return "implements";
 760     else if(nr==KW_INTERFACE)  return "interface";
 761     else if(nr==KW_NAMESPACE)  return "namespace";
 762     else if(nr==KW_PROTECTED)  return "protected";
 763     else if(nr==KW_OVERRIDE)   return "override";
 764     else if(nr==KW_INTERNAL)   return "internal";
 765     else if(nr==KW_FUNCTION)   return "function";
 766     else if(nr==KW_PACKAGE)    return "package";
 767     else if(nr==KW_PRIVATE)    return "private";
 768     else if(nr==KW_BOOLEAN)    return "Boolean";
 769     else if(nr==KW_DYNAMIC)    return "dynamic";
 770     else if(nr==KW_EXTENDS)    return "extends";
 771     else if(nr==KW_PUBLIC)     return "public";
 772     else if(nr==KW_NATIVE)     return "native";
 773     else if(nr==KW_STATIC)     return "static";
 774     else if(nr==KW_IMPORT)     return "import";
 775     else if(nr==KW_NUMBER)     return "number";
 776     else if(nr==KW_CLASS)      return "class";
 777     else if(nr==KW_CONST)      return "const";
 778     else if(nr==KW_FINAL)      return "final";
 779     else if(nr==KW_FALSE)      return "False";
 780     else if(nr==KW_TRUE)       return "True";
 781     else if(nr==KW_UINT)       return "uint";
 782     else if(nr==KW_NULL)       return "null";
 783     else if(nr==KW_ELSE)       return "else";
 784     else if(nr==KW_USE)        return "use";
 785     else if(nr==KW_INT)        return "int";
 786     else if(nr==KW_NEW)        return "new";
 787     else if(nr==KW_GET)        return "get";
 788     else if(nr==KW_SET)        return "set";
 789     else if(nr==KW_VAR)        return "var";
 790     else if(nr==KW_IS)         return "is";
 791     else if(nr==KW_AS)         return "as";
 792     else {
 793         sprintf(mbuf, "%d", nr);
 794         return mbuf;
 795     }
 796 }
 797
 798 void tokenizer_begin_xml()
 799 {
 800     BEGIN(XML);
 801 }
 802 void tokenizer_begin_xmltext()
 803 {
 804     BEGIN(XMLTEXT);
 805 }
 806 void tokenizer_end_xmltext()
 807 {
 808     BEGIN(XML);
 809 }
 810 void tokenizer_end_xml()
 811 {
 812     BEGIN(DEFAULT);
 813 }
 814
 815 void initialize_scanner()
 816 {
 817     BEGIN(BEGINNING);
 818 }
 819
 820