lib/as3/tokenizer.lex

   1 /* tokenizer.lex
   2
   3    Routines for compiling Flash2 AVM2 ABC Actionscript
   4
   5    Extension module for the rfxswf library.
   6    Part of the swftools package.
   7
   8    Copyright (c) 2008 Matthias Kramm <kramm@quiss.org>
   9
  10    This program is free software; you can redistribute it and/or modify
  11    it under the terms of the GNU General Public License as published by
  12    the Free Software Foundation; either version 2 of the License, or
  13    (at your option) any later version.
  14
  15    This program is distributed in the hope that it will be useful,
  16    but WITHOUT ANY WARRANTY; without even the implied warranty of
  17    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18    GNU General Public License for more details.
  19
  20    You should have received a copy of the GNU General Public License
  21    along with this program; if not, write to the Free Software
  22    Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA */
  23 %{
  24
  25
  26 #include <string.h>
  27 #include <stdlib.h>
  28 #include <stdio.h>
  29 #include <stdarg.h>
  30 #include "../utf8.h"
  31 #include "tokenizer.h"
  32 #include "files.h"
  33
  34 int as3_pass = 0;
  35 int as3_verbosity = 1;
  36 unsigned int as3_tokencount = 0;
  37
  38 void as3_error(const char*format, ...)
  39 {
  40     char buf[1024];
  41     int l;
  42     va_list arglist;
  43     if(as3_verbosity<0)
  44         exit(1);
  45     va_start(arglist, format);
  46     vsprintf(buf, format, arglist);
  47     va_end(arglist);
  48     fprintf(stderr, "%s:%d:%d: error: %s\n", current_filename_short, current_line, current_column, buf);
  49     fflush(stderr);
  50     exit(1);
  51 }
  52 void as3_warning(const char*format, ...)
  53 {
  54     char buf[1024];
  55     int l;
  56     va_list arglist;
  57     if(as3_verbosity<1)
  58         return;
  59     va_start(arglist, format);
  60     vsprintf(buf, format, arglist);
  61     va_end(arglist);
  62     fprintf(stderr, "%s:%d:%d: warning: %s\n", current_filename_short, current_line, current_column, buf);
  63     fflush(stderr);
  64 }
  65 void as3_softwarning(const char*format, ...)
  66 {
  67     char buf[1024];
  68     int l;
  69     va_list arglist;
  70     if(as3_verbosity<2)
  71         return;
  72     va_start(arglist, format);
  73     vsprintf(buf, format, arglist);
  74     va_end(arglist);
  75     fprintf(stderr, "%s:%d:%d: warning: %s\n", current_filename_short, current_line, current_column, buf);
  76     fflush(stderr);
  77 }
  78 static void dbg(const char*format, ...)
  79 {
  80     char buf[1024];
  81     int l;
  82     va_list arglist;
  83     if(as3_verbosity<3)
  84         return;
  85     va_start(arglist, format);
  86     vsprintf(buf, format, arglist);
  87     va_end(arglist);
  88     l = strlen(buf);
  89     while(l && buf[l-1]=='\n') {
  90         buf[l-1] = 0;
  91         l--;
  92     }
  93     printf("(tokenizer) ");
  94     printf("%s\n", buf);
  95     fflush(stdout);
  96 }
  97
  98 #ifndef YY_CURRENT_BUFFER
  99 #define YY_CURRENT_BUFFER yy_current_buffer
 100 #endif
 101
 102 static void*as3_buffer=0;
 103 static int as3_buffer_pos=0;
 104 static int as3_buffer_len=0;
 105 void as3_file_input(FILE*fi)
 106 {
 107     as3_in = fi;
 108     as3_buffer = 0;
 109 }
 110 void as3_buffer_input(void*buffer, int len)
 111 {
 112     if(!buffer)
 113         syntaxerror("trying to parse zero bytearray");
 114     as3_buffer = buffer;
 115     as3_buffer_len = len;
 116     as3_buffer_pos = 0;
 117     as3_in = 0;
 118 }
 119
 120 #define YY_INPUT(buf,result,max_size) { \
 121   if(!as3_buffer) { \
 122       errno=0; \
 123       while((result = fread(buf, 1, max_size, as3_in))==0 && ferror(as3_in)) \
 124       { if(errno != EINTR) {YY_FATAL_ERROR("input in flex scanner failed"); break;} \
 125         errno=0; clearerr(as3_in); \
 126       } \
 127   } else { \
 128       int to_read = max_size; \
 129       if(to_read + as3_buffer_pos > as3_buffer_len) \
 130           to_read = as3_buffer_len - as3_buffer_pos; \
 131       memcpy(buf, as3_buffer+as3_buffer_pos, to_read); \
 132       as3_buffer_pos += to_read; \
 133       result=to_read; \
 134   } \
 135 }
 136
 137 void handleInclude(char*text, int len, char quotes)
 138 {
 139     char*filename = 0;
 140     if(quotes) {
 141         char*p1 = strchr(text, '"');
 142         char*p2 = strrchr(text, '"');
 143         if(!p1 || !p2 || p1==p2) {
 144             syntaxerror("Invalid include in line %d\n", current_line);
 145         }
 146         *p2 = 0;
 147         filename = strdup(p1+1);
 148     } else {
 149         int i1=0,i2=len;
 150         // find start
 151         while(!strchr(" \n\r\t", text[i1])) i1++;
 152         // strip
 153         while(strchr(" \n\r\t", text[i1])) i1++;
 154         while(strchr(" \n\r\t", text[i2-1])) i2--;
 155         if(i2!=len) text[i2]=0;
 156         filename = strdup(&text[i1]);
 157     }
 158
 159     char*fullfilename = find_file(filename, 1);
 160     enter_file2(filename, fullfilename, YY_CURRENT_BUFFER);
 161     yyin = fopen(fullfilename, "rb");
 162     if (!yyin) {
 163         syntaxerror("Couldn't open include file \"%s\"\n", fullfilename);
 164     }
 165
 166     yy_switch_to_buffer(yy_create_buffer( yyin, YY_BUF_SIZE ) );
 167     //BEGIN(INITIAL); keep context
 168 }
 169
 170 static int do_unescape(const char*s, const char*end, char*n)
 171 {
 172     char*o = n;
 173     int len=0;
 174     while(s<end) {
 175         if(*s!='\\') {
 176             if(o) o[len] = *s;len++;
 177             s++;
 178             continue;
 179         }
 180         s++; //skip past '\'
 181         if(s==end) syntaxerror("invalid \\ at end of string");
 182
 183         /* handle the various line endings (mac, dos, unix) */
 184         if(*s=='\r') {
 185             s++;
 186             if(s==end) break;
 187             if(*s=='\n')
 188                 s++;
 189             continue;
 190         }
 191         if(*s=='\n')  {
 192             s++;
 193             continue;
 194         }
 195         switch(*s) {
 196             case '\\': if(o) o[len] = '\\';s++;len++; break;
 197             case '"': if(o) o[len] = '"';s++;len++; break;
 198             case '\'': if(o) o[len] = '\'';s++;len++; break;
 199             case 'b': if(o) o[len] = '\b';s++;len++; break;
 200             case 'f': if(o) o[len] = '\f';s++;len++; break;
 201             case 'n': if(o) o[len] = '\n';s++;len++; break;
 202             case 'r': if(o) o[len] = '\r';s++;len++; break;
 203             case 't': if(o) o[len] = '\t';s++;len++; break;
 204             case '0': case '1': case '2': case '3': case '4': case '5': case '6': case '7': {
 205                 unsigned int num=0;
 206                 int nr = 0;
 207                 while(strchr("01234567", *s) && nr<3 && s<end) {
 208                     num <<= 3;
 209                     num |= *s-'0';
 210                     nr++;
 211                     s++;
 212                 }
 213                 if(num>256)
 214                     syntaxerror("octal number out of range (0-255): %d", num);
 215                 if(o) o[len] = num;len++;
 216                 continue;
 217             }
 218             case 'x': case 'u': {
 219                 int max=2;
 220                 char bracket = 0;
 221                 char unicode = 0;
 222                 if(*s == 'u') {
 223                     max = 6;
 224                     unicode = 1;
 225                 }
 226                 s++;
 227                 if(s==end) syntaxerror("invalid \\u or \\x at end of string");
 228                 if(*s == '{')  {
 229                     s++;
 230                     if(s==end) syntaxerror("invalid \\u{ at end of string");
 231                     bracket=1;
 232                 }
 233                 unsigned int num=0;
 234                 int nr = 0;
 235                 while(strchr("0123456789abcdefABCDEF", *s) && (bracket || nr < max) && s<end) {
 236                     num <<= 4;
 237                     if(*s>='0' && *s<='9') num |= *s - '0';
 238                     if(*s>='a' && *s<='f') num |= *s - 'a' + 10;
 239                     if(*s>='A' && *s<='F') num |= *s - 'A' + 10;
 240                     nr++;
 241                     s++;
 242                 }
 243                 if(bracket) {
 244                     if(*s=='}' && s<end) {
 245                         s++;
 246                     } else {
 247                         syntaxerror("missing terminating '}'");
 248                     }
 249                 }
 250                 if(unicode) {
 251                     char*utf8 = getUTF8(num);
 252                     while(*utf8) {
 253                         if(o) o[len] = *utf8;utf8++;len++;
 254                     }
 255                 } else {
 256                     if(num>256)
 257                         syntaxerror("byte out of range (0-255): %d", num);
 258                     if(o) o[len] = num;len++;
 259                 }
 260                 break;
 261             }
 262             default: {
 263                 if(o) {
 264                     o[len+0] = '\\';
 265                     o[len+1] = *s;
 266                 }
 267                 s++;
 268                 len+=2;
 269                 break;
 270             }
 271         }
 272     }
 273     if(o) o[len]=0;
 274     return len;
 275 }
 276
 277 static string_t string_unescape(const char*in, int l)
 278 {
 279     const char*s = in;
 280     const char*end = &in[l];
 281
 282     int len = do_unescape(s, end, 0);
 283     char*n = (char*)malloc(len+1);
 284     do_unescape(s, end, n);
 285     string_t out = string_new(n, len);
 286     return out;
 287 }
 288
 289 static void handleCData(char*s, int len)
 290 {
 291     a3_lval.str.str = s+9;    // <![CDATA[
 292     a3_lval.str.len = len-9-3;// ]]>
 293     a3_lval.str.str = strdup_n(a3_lval.str.str, a3_lval.str.len);
 294 }
 295
 296 static void handleString(char*s, int len)
 297 {
 298     if(as3_pass < 2) {
 299         // don't bother decoding strings in pass 1
 300         memset(&a3_lval, 0, sizeof(a3_lval));
 301         return;
 302     }
 303
 304     if(s[0]=='"') {
 305         if(s[len-1]!='"') syntaxerror("String doesn't end with '\"'");
 306         s++;len-=2;
 307     }
 308     else if(s[0]=='\'') {
 309         if(s[len-1]!='\'') syntaxerror("String doesn't end with '\"'");
 310         s++;len-=2;
 311     }
 312     else syntaxerror("String incorrectly terminated");
 313
 314
 315     a3_lval.str = string_unescape(s, len);
 316 }
 317
 318
 319 char start_of_expression;
 320
 321 static inline int m(int type)
 322 {
 323     a3_lval.token = type;
 324     return type;
 325 }
 326
 327
 328 static char numberbuf[64];
 329 static char*nrbuf()
 330 {
 331     if(yyleng>sizeof(numberbuf)-1)
 332         syntaxerror("decimal number overflow");
 333     char*s = numberbuf;
 334     memcpy(s, yytext, yyleng);
 335     s[yyleng]=0;
 336     return s;
 337 }
 338
 339 static inline int setint(int v)
 340 {
 341     a3_lval.number_int = v;
 342     if(v>-128)
 343         return T_BYTE;
 344     else if(v>=-32768)
 345         return T_SHORT;
 346     else
 347         return T_INT;
 348 }
 349 static inline int setuint(unsigned int v)
 350 {
 351     a3_lval.number_uint = v;
 352     if(v<128)
 353         return T_BYTE;
 354     else if(v<32768)
 355         return T_SHORT;
 356     else
 357         return T_UINT;
 358 }
 359 static inline int setfloat(double v)
 360 {
 361     a3_lval.number_float = v;
 362     return T_FLOAT;
 363 }
 364
 365 static inline int handlefloat()
 366 {
 367     char*s = nrbuf();
 368     a3_lval.number_float = atof(s);
 369     return T_FLOAT;
 370 }
 371
 372 static inline int handleint()
 373 {
 374     char*s = nrbuf();
 375     char l = (yytext[0]=='-');
 376
 377     char*max = l?"1073741824":"2147483647";
 378     if(yyleng-l>10) {
 379         as3_softwarning("integer overflow: %s (converted to Number)", s);
 380         return handlefloat();
 381     }
 382     if(yyleng-l==10) {
 383         int t;
 384         for(t=0;t<yyleng-l;t++) {
 385             if(yytext[l+t]>max[t]) {
 386                 as3_softwarning("integer overflow: %s (converted to Number)", s);
 387                 return handlefloat();
 388             }
 389             else if(yytext[l+t]<max[t])
 390                 break;
 391         }
 392     }
 393     if(yytext[0]=='-') {
 394         int v = atoi(s);
 395         return setint(v);
 396     } else {
 397         unsigned int v = 0;
 398         int t;
 399         for(t=0;t<yyleng;t++) {
 400             v*=10;
 401             v+=yytext[t]-'0';
 402         }
 403         return setuint(v);
 404     }
 405 }
 406
 407 static inline int handlehexfloat()
 408 {
 409     char l = (yytext[0]=='-')+2;
 410     double d=0;
 411     char dot=0;
 412     double base=1;
 413     int t;
 414     for(t=l;t<yyleng;t++) {
 415         char c = yytext[t];
 416         if(c=='.') {
 417             dot=1;
 418             continue;
 419         }
 420         if(!dot) {
 421             d*=16;
 422         } else {
 423             base*=1/16.0;
 424         }
 425         if(c>='0' && c<='9')
 426             d+=(c&15)*base;
 427         else if((c>='a' && c<='f') || (c>='A' && c<='F'))
 428             d+=((c&0x0f)+9)*base;
 429     }
 430     return setfloat(d);
 431 }
 432 static inline int handlehex()
 433 {
 434     char l = (yytext[0]=='-')+2;
 435     int len = yyleng;
 436
 437     if(len-l>8) {
 438         char*s = nrbuf();
 439         syntaxerror("integer overflow %s", s);
 440     }
 441
 442     int t;
 443     unsigned int v = 0;
 444     for(t=l;t<len;t++) {
 445         v<<=4;
 446         char c = yytext[t];
 447         if(c>='0' && c<='9')
 448             v|=(c&15);
 449         else if((c>='a' && c<='f') || (c>='A' && c<='F'))
 450             v|=(c&0x0f)+9;
 451     }
 452     if(l && v>1073741824) {
 453         char*s = nrbuf();
 454         as3_softwarning("signed integer overflow: %s (converted to Number)", s);
 455         return setfloat(v);
 456     }
 457     if(!l && v>2147483647) {
 458         char*s = nrbuf();
 459         as3_softwarning("unsigned integer overflow: %s (converted to Number)", s);
 460         return setfloat(v);
 461     }
 462
 463     if(l==3) {
 464         return setint(-(int)v);
 465     } else {
 466         return setuint(v);
 467     }
 468 }
 469
 470 void handleLabel(char*text, int len)
 471 {
 472     int t;
 473     for(t=len-1;t>=0;--t) {
 474         if(text[t]!=' ' &&
 475            text[t]!=':')
 476             break;
 477     }
 478     char*s = malloc(t+1);
 479     memcpy(s, yytext, t);
 480     s[t]=0;
 481     a3_lval.id = s;
 482 }
 483
 484 static int handleregexp()
 485 {
 486     char*s = malloc(yyleng);
 487     int len=yyleng-1;
 488     memcpy(s, yytext+1, len);
 489     s[len] = 0;
 490     int t;
 491     for(t=len;t>=0;--t) {
 492         if(s[t]=='/') {
 493             s[t] = 0;
 494             break;
 495         }
 496     }
 497     a3_lval.regexp.pattern = s;
 498     if(t==len) {
 499         a3_lval.regexp.options = 0;
 500     } else {
 501         a3_lval.regexp.options = s+t+1;
 502     }
 503     return T_REGEXP;
 504 }
 505
 506 void initialize_scanner();
 507 #define YY_USER_INIT initialize_scanner();
 508
 509 /* count the number of lines+columns consumed by this token */
 510 static inline void l() {
 511     int t;
 512     for(t=0;t<yyleng;t++) {
 513         if(yytext[t]=='\n') {
 514             current_line++;
 515             current_column=0;
 516         } else {
 517             current_column++;
 518         }
 519     }
 520 }
 521 /* count the number of columns consumed by this token */
 522 static inline void c() {
 523     current_column+=yyleng;
 524 }
 525
 526 static trie_t*namespaces = 0;
 527 void tokenizer_register_namespace(const char*id)
 528 {
 529     trie_put(&namespaces, id);
 530 }
 531 static inline tokenizer_is_namespace(const char*id)
 532 {
 533     return trie_lookup(namespaces, id);
 534 }
 535
 536 static inline int handleIdentifier()
 537 {
 538     char*s = malloc(yyleng+1);
 539     memcpy(s, yytext, yyleng);
 540     s[yyleng]=0;
 541     a3_lval.id = s;
 542     if(tokenizer_is_namespace(s))
 543         return T_NAMESPACE;
 544     else
 545         return T_IDENTIFIER;
 546 }
 547
 548
 549 //Boolean                      {c();return m(KW_BOOLEAN);}
 550 //int                          {c();return m(KW_INT);}
 551 //uint                         {c();return m(KW_UINT);}
 552 //Number                       {c();return m(KW_NUMBER);}
 553
 554 %}
 555
 556 %s REGEXPOK
 557 %s BEGINNING
 558
 559 NAME     [a-zA-Z_][a-zA-Z0-9_\\]*
 560 _        [^a-zA-Z0-9_\\]
 561
 562 HEXINT    0x[a-zA-Z0-9]+
 563 HEXFLOAT  0x[a-zA-Z0-9]*\.[a-zA-Z0-9]*
 564 INT       [0-9]+
 565 FLOAT     ([0-9]+(\.[0-9]*)?|\.[0-9]+)(e[0-9]+)?
 566
 567 HEXWITHSIGN [+-]?({HEXINT})
 568 HEXFLOATWITHSIGN [+-]?({HEXFLOAT})
 569 INTWITHSIGN [+-]?({INT})
 570 FLOATWITHSIGN [+-]?({FLOAT})
 571
 572 CDATA    <!\[CDATA\[([^]]|\][^]]|\]\][^>])*\]*\]\]\>
 573 STRING   ["](\\[\x00-\xff]|[^\\"\n])*["]|['](\\[\x00-\xff]|[^\\'\n])*[']
 574 S        [ \n\r\t]
 575 MULTILINE_COMMENT [/][*]+([*][^/]|[^/*]|[^*][/]|[\x00-\x1f])*[*]+[/]
 576 SINGLELINE_COMMENT \/\/[^\n\r]*[\n\r]
 577 REGEXP   [/]([^/\n]|\\[/])*[/][a-zA-Z]*
 578 %%
 579
 580
 581 {SINGLELINE_COMMENT}         {l(); /* single line comment */}
 582 {MULTILINE_COMMENT}          {l(); /* multi line comment */}
 583 [/][*]                       {syntaxerror("syntax error: unterminated comment", yytext);}
 584
 585 ^include{S}+{STRING}{S}*/\n    {l();handleInclude(yytext, yyleng, 1);}
 586 ^include{S}+[^" \t\r\n][\x20-\xff]*{S}*/\n    {l();handleInclude(yytext, yyleng, 0);}
 587 {STRING}                     {l(); BEGIN(INITIAL);handleString(yytext, yyleng);return T_STRING;}
 588 {CDATA}                      {l(); BEGIN(INITIAL);handleCData(yytext, yyleng);return T_STRING;}
 589
 590 <BEGINNING,REGEXPOK>{
 591 {REGEXP}                     {c(); BEGIN(INITIAL);return handleregexp();}
 592 {HEXWITHSIGN}/{_}            {c(); BEGIN(INITIAL);return handlehex();}
 593 {HEXFLOATWITHSIGN}/{_}       {c(); BEGIN(INITIAL);return handlehexfloat();}
 594 {INTWITHSIGN}/{_}            {c(); BEGIN(INITIAL);return handleint();}
 595 {FLOATWITHSIGN}/{_}          {c(); BEGIN(INITIAL);return handlefloat();}
 596 }
 597
 598 <REGEXPOK>[\{]               {c(); BEGIN(REGEXPOK);return m(T_DICTSTART);}
 599 [\{]                         {c(); BEGIN(INITIAL); return m('{');}
 600
 601 \xef\xbb\xbf                 {/* utf 8 bom */}
 602 {S}                          {l();}
 603
 604 {HEXINT}/{_}                 {c(); BEGIN(INITIAL);return handlehex();}
 605 {HEXFLOAT}/{_}               {c(); BEGIN(INITIAL);return handlehexfloat();}
 606 {INT}/{_}                    {c(); BEGIN(INITIAL);return handleint();}
 607 {FLOAT}/{_}                  {c(); BEGIN(INITIAL);return handlefloat();}
 608
 609 3rr0r                        {/* for debugging: generates a tokenizer-level error */
 610                               syntaxerror("3rr0r");}
 611
 612 {NAME}{S}*:{S}*for/{_}       {l();BEGIN(INITIAL);handleLabel(yytext, yyleng-3);return T_FOR;}
 613 {NAME}{S}*:{S}*do/{_}        {l();BEGIN(INITIAL);handleLabel(yytext, yyleng-2);return T_DO;}
 614 {NAME}{S}*:{S}*while/{_}     {l();BEGIN(INITIAL);handleLabel(yytext, yyleng-5);return T_WHILE;}
 615 {NAME}{S}*:{S}*switch/{_}    {l();BEGIN(INITIAL);handleLabel(yytext, yyleng-6);return T_SWITCH;}
 616 for                          {c();BEGIN(INITIAL);a3_lval.id="";return T_FOR;}
 617 do                           {c();BEGIN(INITIAL);a3_lval.id="";return T_DO;}
 618 while                        {c();BEGIN(INITIAL);a3_lval.id="";return T_WHILE;}
 619 switch                       {c();BEGIN(INITIAL);a3_lval.id="";return T_SWITCH;}
 620
 621 [&][&]                       {c();BEGIN(REGEXPOK);return m(T_ANDAND);}
 622 [|][|]                       {c();BEGIN(REGEXPOK);return m(T_OROR);}
 623 [!][=]                       {c();BEGIN(REGEXPOK);return m(T_NE);}
 624 [!][=][=]                    {c();BEGIN(REGEXPOK);return m(T_NEE);}
 625 [=][=][=]                    {c();BEGIN(REGEXPOK);return m(T_EQEQEQ);}
 626 [=][=]                       {c();BEGIN(REGEXPOK);return m(T_EQEQ);}
 627 [>][=]                       {c();BEGIN(REGEXPOK);return m(T_GE);}
 628 [<][=]                       {c();BEGIN(REGEXPOK);return m(T_LE);}
 629 [-][-]                       {c();BEGIN(INITIAL);return m(T_MINUSMINUS);}
 630 [+][+]                       {c();BEGIN(INITIAL);return m(T_PLUSPLUS);}
 631 [+][=]                       {c();BEGIN(REGEXPOK);return m(T_PLUSBY);}
 632 [\^][=]                      {c();BEGIN(REGEXPOK);return m(T_XORBY);}
 633 [-][=]                       {c();BEGIN(REGEXPOK);return m(T_MINUSBY);}
 634 [/][=]                       {c();BEGIN(REGEXPOK);return m(T_DIVBY);}
 635 [%][=]                       {c();BEGIN(REGEXPOK);return m(T_MODBY);}
 636 [*][=]                       {c();BEGIN(REGEXPOK);return m(T_MULBY);}
 637 [|][=]                       {c();BEGIN(REGEXPOK);return m(T_ORBY);}
 638 [>][>][=]                    {c();BEGIN(REGEXPOK);return m(T_SHRBY);}
 639 [<][<][=]                    {c();BEGIN(REGEXPOK);return m(T_SHLBY);}
 640 [>][>][>][=]                 {c();BEGIN(REGEXPOK);return m(T_USHRBY);}
 641 [<][<]                       {c();BEGIN(REGEXPOK);return m(T_SHL);}
 642 [>][>][>]                    {c();BEGIN(REGEXPOK);return m(T_USHR);}
 643 [>][>]                       {c();BEGIN(REGEXPOK);return m(T_SHR);}
 644 \.\.\.                       {c();BEGIN(REGEXPOK);return m(T_DOTDOTDOT);}
 645 \.\.                         {c();BEGIN(REGEXPOK);return m(T_DOTDOT);}
 646 \.                           {c();BEGIN(REGEXPOK);return m('.');}
 647 ::                           {c();BEGIN(REGEXPOK);return m(T_COLONCOLON);}
 648 :                            {c();BEGIN(REGEXPOK);return m(':');}
 649 instanceof                   {c();BEGIN(REGEXPOK);return m(KW_INSTANCEOF);}
 650 implements                   {c();BEGIN(REGEXPOK);return m(KW_IMPLEMENTS);}
 651 interface                    {c();BEGIN(INITIAL);return m(KW_INTERFACE);}
 652 namespace                    {c();BEGIN(INITIAL);return m(KW_NAMESPACE);}
 653 protected                    {c();BEGIN(INITIAL);return m(KW_PROTECTED);}
 654 undefined                    {c();BEGIN(INITIAL);return m(KW_UNDEFINED);}
 655 continue                     {c();BEGIN(INITIAL);return m(KW_CONTINUE);}
 656 override                     {c();BEGIN(INITIAL);return m(KW_OVERRIDE);}
 657 internal                     {c();BEGIN(INITIAL);return m(KW_INTERNAL);}
 658 function                     {c();BEGIN(INITIAL);return m(KW_FUNCTION);}
 659 finally                      {c();BEGIN(INITIAL);return m(KW_FINALLY);}
 660 default                      {c();BEGIN(INITIAL);return m(KW_DEFAULT);}
 661 package                      {c();BEGIN(INITIAL);return m(KW_PACKAGE);}
 662 private                      {c();BEGIN(INITIAL);return m(KW_PRIVATE);}
 663 dynamic                      {c();BEGIN(INITIAL);return m(KW_DYNAMIC);}
 664 extends                      {c();BEGIN(INITIAL);return m(KW_EXTENDS);}
 665 delete                       {c();BEGIN(REGEXPOK);return m(KW_DELETE);}
 666 return                       {c();BEGIN(REGEXPOK);return m(KW_RETURN);}
 667 public                       {c();BEGIN(INITIAL);return m(KW_PUBLIC);}
 668 native                       {c();BEGIN(INITIAL);return m(KW_NATIVE);}
 669 static                       {c();BEGIN(INITIAL);return m(KW_STATIC);}
 670 import                       {c();BEGIN(REGEXPOK);return m(KW_IMPORT);}
 671 typeof                       {c();BEGIN(REGEXPOK);return m(KW_TYPEOF);}
 672 throw                        {c();BEGIN(REGEXPOK);return m(KW_THROW);}
 673 class                        {c();BEGIN(INITIAL);return m(KW_CLASS);}
 674 const                        {c();BEGIN(INITIAL);return m(KW_CONST);}
 675 catch                        {c();BEGIN(INITIAL);return m(KW_CATCH);}
 676 final                        {c();BEGIN(INITIAL);return m(KW_FINAL);}
 677 false                        {c();BEGIN(INITIAL);return m(KW_FALSE);}
 678 break                        {c();BEGIN(INITIAL);return m(KW_BREAK);}
 679 super                        {c();BEGIN(INITIAL);return m(KW_SUPER);}
 680 each                         {c();BEGIN(INITIAL);return m(KW_EACH);}
 681 void                         {c();BEGIN(INITIAL);return m(KW_VOID);}
 682 true                         {c();BEGIN(INITIAL);return m(KW_TRUE);}
 683 null                         {c();BEGIN(INITIAL);return m(KW_NULL);}
 684 else                         {c();BEGIN(INITIAL);return m(KW_ELSE);}
 685 case                         {c();BEGIN(REGEXPOK);return m(KW_CASE);}
 686 with                         {c();BEGIN(REGEXPOK);return m(KW_WITH);}
 687 use                          {c();BEGIN(REGEXPOK);return m(KW_USE);}
 688 new                          {c();BEGIN(REGEXPOK);return m(KW_NEW);}
 689 get                          {c();BEGIN(INITIAL);return m(KW_GET);}
 690 set                          {c();BEGIN(INITIAL);return m(KW_SET);}
 691 var                          {c();BEGIN(INITIAL);return m(KW_VAR);}
 692 try                          {c();BEGIN(INITIAL);return m(KW_TRY);}
 693 is                           {c();BEGIN(REGEXPOK);return m(KW_IS) ;}
 694 in                           {c();BEGIN(REGEXPOK);return m(KW_IN) ;}
 695 if                           {c();BEGIN(INITIAL);return m(KW_IF) ;}
 696 as                           {c();BEGIN(REGEXPOK);return m(KW_AS);}
 697 $?{NAME}                       {c();BEGIN(INITIAL);return handleIdentifier();}
 698
 699 [\]\}*]                       {c();BEGIN(INITIAL);return m(yytext[0]);}
 700 [+-\/^~@$!%&\(=\[|?:;,<>]   {c();BEGIN(REGEXPOK);return m(yytext[0]);}
 701 [\)\]]                           {c();BEGIN(INITIAL);return m(yytext[0]);}
 702
 703 .                            {/* ERROR */
 704                               char c1=yytext[0];
 705                               char buf[128];
 706                               buf[0] = yytext[0];
 707                               int t;
 708                               for(t=1;t<128;t++) {
 709                                   char c = buf[t]=input();
 710                                   if(c=='\n' || c==EOF)  {
 711                                       buf[t] = 0;
 712                                       break;
 713                                   }
 714                               }
 715                               if(c1>='0' && c1<='9')
 716                                   syntaxerror("syntax error: %s (identifiers must not start with a digit)");
 717                               else
 718                                   syntaxerror("syntax error: %s", buf);
 719                               printf("\n");
 720                               exit(1);
 721                               yyterminate();
 722                              }
 723 <<EOF>>                      {l();
 724                               void*b = leave_file();
 725                               if (!b) {
 726                                  yyterminate();
 727                                  yy_delete_buffer(YY_CURRENT_BUFFER);
 728                                  return m(T_EOF);
 729                               } else {
 730                                   yy_delete_buffer(YY_CURRENT_BUFFER);
 731                                   yy_switch_to_buffer(b);
 732                               }
 733                              }
 734
 735 %%
 736
 737 int yywrap()
 738 {
 739     return 1;
 740 }
 741
 742 static char mbuf[256];
 743 char*token2string(enum yytokentype nr, YYSTYPE v)
 744 {
 745     if(nr==T_STRING) {
 746         char*s = malloc(v.str.len+10);
 747         strcpy(s, "<string>");
 748         memcpy(s+8, v.str.str, v.str.len);
 749         sprintf(s+8+v.str.len, " (%d bytes)", v.str.len);
 750         return s;
 751     }
 752     else if(nr==T_REGEXP) {
 753         char*s = malloc(strlen(v.regexp.pattern)+10);
 754         sprintf(s, "<regexp>%s", v.regexp.pattern);
 755         return s;
 756     }
 757     else if(nr==T_IDENTIFIER) {
 758         char*s = malloc(strlen(v.id)+10);
 759         sprintf(s, "<ID>%s", v.id);
 760         return s;
 761     }
 762     else if(nr==T_INT)     return "<int>";
 763     else if(nr==T_UINT)     return "<uint>";
 764     else if(nr==T_BYTE)     return "<byte>";
 765     else if(nr==T_FLOAT)     return "<float>";
 766     else if(nr==T_EOF)        return "***END***";
 767     else if(nr==T_GE)         return ">=";
 768     else if(nr==T_LE)         return "<=";
 769     else if(nr==T_MINUSMINUS) return "--";
 770     else if(nr==T_PLUSPLUS)   return "++";
 771     else if(nr==KW_IMPLEMENTS) return "implements";
 772     else if(nr==KW_INTERFACE)  return "interface";
 773     else if(nr==KW_NAMESPACE)  return "namespace";
 774     else if(nr==KW_PROTECTED)  return "protected";
 775     else if(nr==KW_OVERRIDE)   return "override";
 776     else if(nr==KW_INTERNAL)   return "internal";
 777     else if(nr==KW_FUNCTION)   return "function";
 778     else if(nr==KW_PACKAGE)    return "package";
 779     else if(nr==KW_PRIVATE)    return "private";
 780     else if(nr==KW_BOOLEAN)    return "Boolean";
 781     else if(nr==KW_DYNAMIC)    return "dynamic";
 782     else if(nr==KW_EXTENDS)    return "extends";
 783     else if(nr==KW_PUBLIC)     return "public";
 784     else if(nr==KW_NATIVE)     return "native";
 785     else if(nr==KW_STATIC)     return "static";
 786     else if(nr==KW_IMPORT)     return "import";
 787     else if(nr==KW_NUMBER)     return "number";
 788     else if(nr==KW_CLASS)      return "class";
 789     else if(nr==KW_CONST)      return "const";
 790     else if(nr==KW_FINAL)      return "final";
 791     else if(nr==KW_FALSE)      return "False";
 792     else if(nr==KW_TRUE)       return "True";
 793     else if(nr==KW_UINT)       return "uint";
 794     else if(nr==KW_NULL)       return "null";
 795     else if(nr==KW_ELSE)       return "else";
 796     else if(nr==KW_USE)        return "use";
 797     else if(nr==KW_INT)        return "int";
 798     else if(nr==KW_NEW)        return "new";
 799     else if(nr==KW_GET)        return "get";
 800     else if(nr==KW_SET)        return "set";
 801     else if(nr==KW_VAR)        return "var";
 802     else if(nr==KW_IS)         return "is";
 803     else if(nr==KW_AS)         return "as";
 804     else {
 805         sprintf(mbuf, "%d", nr);
 806         return mbuf;
 807     }
 808 }
 809
 810 void initialize_scanner()
 811 {
 812     BEGIN(BEGINNING);
 813 }
 814
 815