lib/as3/tokenizer.lex

   1 /* tokenizer.lex
   2
   3    Routines for compiling Flash2 AVM2 ABC Actionscript
   4
   5    Extension module for the rfxswf library.
   6    Part of the swftools package.
   7
   8    Copyright (c) 2008 Matthias Kramm <kramm@quiss.org>
   9
  10    This program is free software; you can redistribute it and/or modify
  11    it under the terms of the GNU General Public License as published by
  12    the Free Software Foundation; either version 2 of the License, or
  13    (at your option) any later version.
  14
  15    This program is distributed in the hope that it will be useful,
  16    but WITHOUT ANY WARRANTY; without even the implied warranty of
  17    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18    GNU General Public License for more details.
  19
  20    You should have received a copy of the GNU General Public License
  21    along with this program; if not, write to the Free Software
  22    Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA */
  23 %{
  24
  25
  26 #include <string.h>
  27 #include <stdlib.h>
  28 #include <stdio.h>
  29 #include <stdarg.h>
  30 #include "../utf8.h"
  31 #include "common.h"
  32 #include "tokenizer.h"
  33 #include "files.h"
  34
  35 unsigned int as3_tokencount = 0;
  36
  37 static void dbg(const char*format, ...)
  38 {
  39     char buf[1024];
  40     int l;
  41     va_list arglist;
  42     if(as3_verbosity<3)
  43         return;
  44     va_start(arglist, format);
  45     vsnprintf(buf, sizeof(buf)-1, format, arglist);
  46     va_end(arglist);
  47     l = strlen(buf);
  48     while(l && buf[l-1]=='\n') {
  49         buf[l-1] = 0;
  50         l--;
  51     }
  52     printf("(tokenizer) ");
  53     printf("%s\n", buf);
  54     fflush(stdout);
  55 }
  56
  57 #ifndef YY_CURRENT_BUFFER
  58 #define YY_CURRENT_BUFFER yy_current_buffer
  59 #endif
  60
  61 static void*as3_buffer=0;
  62 static int as3_buffer_pos=0;
  63 static int as3_buffer_len=0;
  64 void as3_file_input(FILE*fi)
  65 {
  66     as3_in = fi;
  67     as3_buffer = 0;
  68 }
  69 void as3_buffer_input(void*buffer, int len)
  70 {
  71     if(!buffer)
  72         syntaxerror("trying to parse zero bytearray");
  73     as3_buffer = buffer;
  74     as3_buffer_len = len;
  75     as3_buffer_pos = 0;
  76     as3_in = 0;
  77 }
  78
  79 //#undef BEGIN
  80 //#define BEGIN(x) {(yy_start) = 1 + 2 *x;dbg("entering state %d", x);}
  81
  82 #define YY_INPUT(buf,result,max_size) { \
  83   if(!as3_buffer) { \
  84       errno=0; \
  85       while((result = fread(buf, 1, max_size, as3_in))==0 && ferror(as3_in)) \
  86       { if(errno != EINTR) {YY_FATAL_ERROR("input in flex scanner failed"); break;} \
  87         errno=0; clearerr(as3_in); \
  88       } \
  89   } else { \
  90       int to_read = max_size; \
  91       if(to_read + as3_buffer_pos > as3_buffer_len) \
  92           to_read = as3_buffer_len - as3_buffer_pos; \
  93       memcpy(buf, as3_buffer+as3_buffer_pos, to_read); \
  94       as3_buffer_pos += to_read; \
  95       result=to_read; \
  96   } \
  97 }
  98
  99 void handleInclude(char*text, int len, char quotes)
 100 {
 101     char*filename = 0;
 102     if(quotes) {
 103         char*p1 = strchr(text, '"');
 104         char*p2 = strrchr(text, '"');
 105         if(!p1 || !p2 || p1==p2) {
 106             syntaxerror("Invalid include in line %d\n", current_line);
 107         }
 108         *p2 = 0;
 109         filename = strdup(p1+1);
 110     } else {
 111         int i1=0,i2=len;
 112         // find start
 113         while(!strchr(" \n\r\t\xa0", text[i1])) i1++;
 114         // strip
 115         while(strchr(" \n\r\t\xa0", text[i1])) i1++;
 116         while(strchr(" \n\r\t\xa0", text[i2-1])) i2--;
 117         if(i2!=len) text[i2]=0;
 118         filename = strdup(&text[i1]);
 119     }
 120
 121     char*fullfilename = find_file(filename, 1);
 122     enter_file2(filename, fullfilename, YY_CURRENT_BUFFER);
 123     yyin = fopen(fullfilename, "rb");
 124     if (!yyin) {
 125         syntaxerror("Couldn't open include file \"%s\"\n", fullfilename);
 126     }
 127
 128     yy_switch_to_buffer(yy_create_buffer( yyin, YY_BUF_SIZE ) );
 129     //BEGIN(DEFAULT); keep context
 130 }
 131
 132 static int do_unescape(const char*s, const char*end, char*n)
 133 {
 134     char*o = n;
 135     int len=0;
 136     while(s<end) {
 137         if(*s!='\\') {
 138             if(o) o[len] = *s;len++;
 139             s++;
 140             continue;
 141         }
 142         s++; //skip past '\'
 143         if(s==end) syntaxerror("invalid \\ at end of string");
 144
 145         /* handle the various line endings (mac, dos, unix) */
 146         if(*s=='\r') {
 147             s++;
 148             if(s==end) break;
 149             if(*s=='\n')
 150                 s++;
 151             continue;
 152         }
 153         if(*s=='\n')  {
 154             s++;
 155             continue;
 156         }
 157         switch(*s) {
 158             case '\\': if(o) o[len] = '\\';s++;len++; break;
 159             case '"': if(o) o[len] = '"';s++;len++; break;
 160             case '\'': if(o) o[len] = '\'';s++;len++; break;
 161             case 'b': if(o) o[len] = '\b';s++;len++; break;
 162             case 'f': if(o) o[len] = '\f';s++;len++; break;
 163             case 'n': if(o) o[len] = '\n';s++;len++; break;
 164             case 'r': if(o) o[len] = '\r';s++;len++; break;
 165             case 't': if(o) o[len] = '\t';s++;len++; break;
 166             case '0': case '1': case '2': case '3': case '4': case '5': case '6': case '7': {
 167                 unsigned int num=0;
 168                 int nr = 0;
 169                 while(strchr("01234567", *s) && nr<3 && s<end) {
 170                     num <<= 3;
 171                     num |= *s-'0';
 172                     nr++;
 173                     s++;
 174                 }
 175                 if(num>256)
 176                     syntaxerror("octal number out of range (0-255): %d", num);
 177                 if(o) o[len] = num;len++;
 178                 continue;
 179             }
 180             case 'x': case 'u': {
 181                 int max=2;
 182                 char bracket = 0;
 183                 char unicode = 0;
 184                 if(*s == 'u') {
 185                     max = 6;
 186                     unicode = 1;
 187                 }
 188                 s++;
 189                 if(s==end) syntaxerror("invalid \\u or \\x at end of string");
 190                 if(*s == '{')  {
 191                     s++;
 192                     if(s==end) syntaxerror("invalid \\u{ at end of string");
 193                     bracket=1;
 194                 }
 195                 unsigned int num=0;
 196                 int nr = 0;
 197                 while(strchr("0123456789abcdefABCDEF", *s) && (bracket || nr < max) && s<end) {
 198                     num <<= 4;
 199                     if(*s>='0' && *s<='9') num |= *s - '0';
 200                     if(*s>='a' && *s<='f') num |= *s - 'a' + 10;
 201                     if(*s>='A' && *s<='F') num |= *s - 'A' + 10;
 202                     nr++;
 203                     s++;
 204                 }
 205                 if(bracket) {
 206                     if(*s=='}' && s<end) {
 207                         s++;
 208                     } else {
 209                         syntaxerror("missing terminating '}'");
 210                     }
 211                 }
 212                 if(unicode) {
 213                     char*utf8 = getUTF8(num);
 214                     while(*utf8) {
 215                         if(o) o[len] = *utf8;utf8++;len++;
 216                     }
 217                 } else {
 218                     if(num>256)
 219                         syntaxerror("byte out of range (0-255): %d", num);
 220                     if(o) o[len] = num;len++;
 221                 }
 222                 break;
 223             }
 224             default: {
 225                 if(o) {
 226                     o[len+0] = '\\';
 227                     o[len+1] = *s;
 228                 }
 229                 s++;
 230                 len+=2;
 231                 break;
 232             }
 233         }
 234     }
 235     if(o) o[len]=0;
 236     return len;
 237 }
 238
 239 static string_t string_unescape(const char*in, int l)
 240 {
 241     const char*s = in;
 242     const char*end = &in[l];
 243
 244     int len = do_unescape(s, end, 0);
 245     char*n = (char*)malloc(len+1);
 246     do_unescape(s, end, n);
 247     string_t out = string_new(n, len);
 248     return out;
 249 }
 250
 251 static void handleCData(char*s, int len)
 252 {
 253     a3_lval.str.str = s+9;    // <![CDATA[
 254     a3_lval.str.len = len-9-3;// ]]>
 255     a3_lval.str.str = strdup_n(a3_lval.str.str, a3_lval.str.len);
 256 }
 257
 258 static void handleRaw(char*s, int len)
 259 {
 260     a3_lval.str.len = len;
 261     a3_lval.str.str = strdup_n(s, a3_lval.str.len);
 262 }
 263
 264 static void handleString(char*s, int len)
 265 {
 266     if(s[0]=='"') {
 267         if(s[len-1]!='"') syntaxerror("String doesn't end with '\"'");
 268         s++;len-=2;
 269     }
 270     else if(s[0]=='\'') {
 271         if(s[len-1]!='\'') syntaxerror("String doesn't end with '\"'");
 272         s++;len-=2;
 273     }
 274     else syntaxerror("String incorrectly terminated");
 275
 276     a3_lval.str = string_unescape(s, len);
 277 }
 278
 279
 280 char start_of_expression;
 281
 282 static inline int m(int type)
 283 {
 284     a3_lval.token = type;
 285     return type;
 286 }
 287
 288 static char numberbuf[64];
 289 static char*nrbuf()
 290 {
 291     if(yyleng>sizeof(numberbuf)-1)
 292         syntaxerror("decimal number overflow");
 293     char*s = numberbuf;
 294     memcpy(s, yytext, yyleng);
 295     s[yyleng]=0;
 296     return s;
 297 }
 298
 299 static inline int setint(int v)
 300 {
 301     a3_lval.number_int = v;
 302     return T_INT;
 303 }
 304 static inline int setfloat(double v)
 305 {
 306     a3_lval.number_float = v;
 307     return T_FLOAT;
 308 }
 309
 310 static inline int handlefloat()
 311 {
 312     char*s = nrbuf();
 313     a3_lval.number_float = atof(s);
 314     return T_FLOAT;
 315 }
 316
 317 static inline int handleint()
 318 {
 319     char*s = nrbuf();
 320     char l = (yytext[0]=='-');
 321
 322     //char*max = l?"1073741824":"2147483647";
 323     char*max = l?"2147483648":"2147483647";
 324
 325     if(yyleng-l>10) {
 326         as3_softwarning("integer overflow: %s (converted to Number)", s);
 327         return handlefloat();
 328     }
 329     if(yyleng-l==10) {
 330         int t;
 331         for(t=0;t<yyleng-l;t++) {
 332             if(yytext[l+t]>max[t]) {
 333                 as3_softwarning("integer overflow: %s (converted to Number)", s);
 334                 return handlefloat();
 335             }
 336             else if(yytext[l+t]<max[t])
 337                 break;
 338         }
 339     }
 340     if(yytext[0]=='-') {
 341         int v = atoi(s);
 342         return setint(v);
 343     } else {
 344         unsigned int v = 0;
 345         int t;
 346         for(t=0;t<yyleng;t++) {
 347             v*=10;
 348             v+=yytext[t]-'0';
 349         }
 350         return setint(v);
 351     }
 352 }
 353
 354 static inline int handlehexfloat()
 355 {
 356     char l = (yytext[0]=='-')+2;
 357     double d=0;
 358     char dot=0;
 359     double base=1;
 360     int t;
 361     for(t=l;t<yyleng;t++) {
 362         char c = yytext[t];
 363         if(c=='.') {
 364             dot=1;
 365             continue;
 366         }
 367         if(!dot) {
 368             d*=16;
 369         } else {
 370             base*=1/16.0;
 371         }
 372         if(c>='0' && c<='9')
 373             d+=(c&15)*base;
 374         else if((c>='a' && c<='f') || (c>='A' && c<='F'))
 375             d+=((c&0x0f)+9)*base;
 376     }
 377     return setfloat(d);
 378 }
 379 static inline int handlehex()
 380 {
 381     char l = (yytext[0]=='-')+2;
 382     int len = yyleng;
 383
 384     if(len-l>8) {
 385         char*s = nrbuf();
 386         syntaxerror("integer overflow %s", s);
 387     }
 388
 389     int t;
 390     unsigned int v = 0;
 391     for(t=l;t<len;t++) {
 392         v<<=4;
 393         char c = yytext[t];
 394         if(c>='0' && c<='9')
 395             v|=(c&15);
 396         else if((c>='a' && c<='f') || (c>='A' && c<='F'))
 397             v|=(c&0x0f)+9;
 398     }
 399     if(l && v>=0x80000000) {
 400         char*s = nrbuf();
 401         as3_softwarning("integer overflow: %s (converted to Number)", s);
 402         return setfloat(v);
 403     }
 404     if(!l && v>0x7fffffff) {
 405         char*s = nrbuf();
 406         as3_softwarning("integer overflow: %s (converted to Number)", s);
 407         return setfloat(v);
 408     }
 409
 410     if(l==3) {
 411         return setint(-(int)v);
 412     } else {
 413         return setint(v);
 414     }
 415 }
 416
 417 void handleLabel(char*text, int len)
 418 {
 419     int t;
 420     for(t=len-1;t>=0;--t) {
 421         if(text[t]!=' ' &&
 422            text[t]!=':')
 423             break;
 424     }
 425     char*s = malloc(t+1);
 426     memcpy(s, yytext, t);
 427     s[t]=0;
 428     a3_lval.id = s;
 429 }
 430
 431 static int handleregexp()
 432 {
 433     char*s = malloc(yyleng);
 434     int len=yyleng-1;
 435     memcpy(s, yytext+1, len);
 436     s[len] = 0;
 437     int t;
 438     for(t=len;t>=0;--t) {
 439         if(s[t]=='/') {
 440             s[t] = 0;
 441             break;
 442         }
 443     }
 444     a3_lval.regexp.pattern = s;
 445     if(t==len) {
 446         a3_lval.regexp.options = 0;
 447     } else {
 448         a3_lval.regexp.options = s+t+1;
 449     }
 450     return T_REGEXP;
 451 }
 452
 453 void initialize_scanner();
 454 #define YY_USER_INIT initialize_scanner();
 455
 456 /* count the number of lines+columns consumed by this token */
 457 static inline void l() {
 458     int t;
 459     for(t=0;t<yyleng;t++) {
 460         if(yytext[t]=='\n') {
 461             current_line++;
 462             current_column=0;
 463         } else {
 464             current_column++;
 465         }
 466     }
 467 }
 468 /* count the number of columns consumed by this token */
 469 static inline void c() {
 470     current_column+=yyleng;
 471 }
 472
 473 trie_t*active_namespaces = 0;
 474 /*void tokenizer_register_namespace(const char*id)
 475 {
 476     trie_put(namespaces, id, 0);
 477 }
 478 void tokenizer_unregister_namespace(const char*id)
 479 {
 480     trie_remove(namespaces, id);
 481 }*/
 482 static inline char tokenizer_is_namespace(const char*id)
 483 {
 484     return trie_contains(active_namespaces, id);
 485 }
 486
 487 static inline int handleIdentifier()
 488 {
 489     char*s = malloc(yyleng+1);
 490     memcpy(s, yytext, yyleng);
 491     s[yyleng]=0;
 492     a3_lval.id = s;
 493     if(tokenizer_is_namespace(s))
 494         return T_NAMESPACE;
 495     else
 496         return T_IDENTIFIER;
 497 }
 498 static int tokenerror();
 499
 500
 501 //Boolean                      {c();return m(KW_BOOLEAN);}
 502 //int                          {c();return m(KW_INT);}
 503 //uint                         {c();return m(KW_UINT);}
 504 //Number                       {c();return m(KW_NUMBER);}
 505 //XMLCOMMENT  <!--([^->]|(-/[^-])|(--/[^>]))*-->
 506
 507 //{XMLCOMMENT}
 508
 509 %}
 510
 511 %s REGEXPOK
 512 %s BEGINNING
 513 %s DEFAULT
 514 %x XMLTEXT
 515 %x XML
 516
 517 NAME     [a-zA-Z_][a-zA-Z0-9_\\]*
 518 _        [^a-zA-Z0-9_\\]
 519
 520 HEXINT    0x[a-zA-Z0-9]+
 521 HEXFLOAT  0x[a-zA-Z0-9]*\.[a-zA-Z0-9]*
 522 INT       [0-9]+
 523 FLOAT     ([0-9]+(\.[0-9]*)?|\.[0-9]+)(e[0-9]+)?
 524
 525 HEXWITHSIGN [+-]?({HEXINT})
 526 HEXFLOATWITHSIGN [+-]?({HEXFLOAT})
 527 INTWITHSIGN [+-]?({INT})
 528 FLOATWITHSIGN [+-]?({FLOAT})
 529
 530 CDATA       <!\[CDATA\[([^]]|\][^]]|\]\][^>])*\]*\]\]\>
 531 XMLCOMMENT  <!--([^->]|[-]+[^>-]|>)*-*-->
 532 XML         <[^>]+{S}>
 533 XMLID       [A-Za-z0-9_\x80-\xff]+([:][A-Za-z0-9_\x80-\xff]+)?
 534 XMLSTRING   ["][^"]*["]
 535
 536 STRING   ["](\\[\x00-\xff]|[^\\"\n])*["]|['](\\[\x00-\xff]|[^\\'\n])*[']
 537 S        [ \n\r\t\xa0]
 538 MULTILINE_COMMENT [/][*]+([*][^/]|[^/*]|[^*][/]|[\x00-\x1f])*[*]+[/]
 539 SINGLELINE_COMMENT \/\/[^\n\r]*[\n\r]
 540 REGEXP   [/]([^/\n]|\\[/])*[/][a-zA-Z]*
 541 %%
 542
 543
 544 {SINGLELINE_COMMENT}         {l(); /* single line comment */}
 545 {MULTILINE_COMMENT}          {l(); /* multi line comment */}
 546 [/][*]                       {syntaxerror("syntax error: unterminated comment", yytext);}
 547
 548 ^include{S}+{STRING}{S}*/\n    {l();handleInclude(yytext, yyleng, 1);}
 549 ^include{S}+[^" \t\xa0\r\n][\x20-\xff]*{S}*/\n    {l();handleInclude(yytext, yyleng, 0);}
 550 {STRING}                     {l(); BEGIN(DEFAULT);handleString(yytext, yyleng);return T_STRING;}
 551 {CDATA}                      {l(); BEGIN(DEFAULT);handleCData(yytext, yyleng);return T_STRING;}
 552
 553 <DEFAULT,BEGINNING,REGEXPOK>{
 554 {XMLCOMMENT}                 {l(); BEGIN(DEFAULT);handleRaw(yytext, yyleng);return T_STRING;}
 555 }
 556
 557 <XML>{
 558 {XMLSTRING}                  {l(); handleRaw(yytext, yyleng);return T_STRING;}
 559 [{]                          {c(); BEGIN(REGEXPOK);return m('{');}
 560 [<]                          {c(); return m('<');}
 561 [/]                          {c(); return m('/');}
 562 [>]                          {c(); return m('>');}
 563 [=]                          {c(); return m('=');}
 564 {XMLID}                      {c(); handleRaw(yytext, yyleng);return T_IDENTIFIER;}
 565 {S}                          {l();}
 566 <<EOF>>                      {syntaxerror("unexpected end of file");}
 567 }
 568
 569 <XMLTEXT>{
 570 [^<>{]+                      {l(); handleRaw(yytext, yyleng);return T_STRING;}
 571 [{]                          {c(); BEGIN(REGEXPOK);return m('{');}
 572 [<]                          {c(); BEGIN(XML);return m('<');}
 573 [>]                          {c(); return m('>');}
 574 {XMLCOMMENT}                 {l(); handleRaw(yytext, yyleng);return T_STRING;}
 575 {CDATA}                      {l(); handleRaw(yytext, yyleng);return T_STRING;}
 576 <<EOF>>                      {syntaxerror("unexpected end of file");}
 577 }
 578
 579 <BEGINNING,REGEXPOK>{
 580 {REGEXP}                     {c(); BEGIN(DEFAULT);return handleregexp();}
 581 {HEXWITHSIGN}/{_}            {c(); BEGIN(DEFAULT);return handlehex();}
 582 {HEXFLOATWITHSIGN}/{_}       {c(); BEGIN(DEFAULT);return handlehexfloat();}
 583 {INTWITHSIGN}/{_}            {c(); BEGIN(DEFAULT);return handleint();}
 584 {FLOATWITHSIGN}/{_}          {c(); BEGIN(DEFAULT);return handlefloat();}
 585 }
 586
 587 <REGEXPOK>[\{]               {c(); BEGIN(REGEXPOK);return m(T_DICTSTART);}
 588 [\{]                         {c(); BEGIN(DEFAULT); return m('{');}
 589
 590 \xef\xbb\xbf                 {/* utf 8 bom */}
 591 {S}                          {l();}
 592
 593 {HEXINT}/{_}                 {c(); BEGIN(DEFAULT);return handlehex();}
 594 {HEXFLOAT}/{_}               {c(); BEGIN(DEFAULT);return handlehexfloat();}
 595 {INT}/{_}                    {c(); BEGIN(DEFAULT);return handleint();}
 596 {FLOAT}/{_}                  {c(); BEGIN(DEFAULT);return handlefloat();}
 597 NaN                          {c(); BEGIN(DEFAULT);return m(KW_NAN);}
 598
 599 3rr0r                        {/* for debugging: generates a tokenizer-level error */
 600                               syntaxerror("3rr0r");}
 601
 602 {NAME}{S}*:{S}*for/{_}       {l();BEGIN(DEFAULT);handleLabel(yytext, yyleng-3);return T_FOR;}
 603 {NAME}{S}*:{S}*do/{_}        {l();BEGIN(DEFAULT);handleLabel(yytext, yyleng-2);return T_DO;}
 604 {NAME}{S}*:{S}*while/{_}     {l();BEGIN(DEFAULT);handleLabel(yytext, yyleng-5);return T_WHILE;}
 605 {NAME}{S}*:{S}*switch/{_}    {l();BEGIN(DEFAULT);handleLabel(yytext, yyleng-6);return T_SWITCH;}
 606 default{S}xml                {l();BEGIN(DEFAULT);return m(KW_DEFAULT_XML);}
 607 for                          {c();BEGIN(DEFAULT);a3_lval.id="";return T_FOR;}
 608 do                           {c();BEGIN(DEFAULT);a3_lval.id="";return T_DO;}
 609 while                        {c();BEGIN(DEFAULT);a3_lval.id="";return T_WHILE;}
 610 switch                       {c();BEGIN(DEFAULT);a3_lval.id="";return T_SWITCH;}
 611
 612 [&][&]                       {c();BEGIN(REGEXPOK);return m(T_ANDAND);}
 613 [|][|]                       {c();BEGIN(REGEXPOK);return m(T_OROR);}
 614 [!][=]                       {c();BEGIN(REGEXPOK);return m(T_NE);}
 615 [!][=][=]                    {c();BEGIN(REGEXPOK);return m(T_NEE);}
 616 [=][=][=]                    {c();BEGIN(REGEXPOK);return m(T_EQEQEQ);}
 617 [=][=]                       {c();BEGIN(REGEXPOK);return m(T_EQEQ);}
 618 [>][=]                       {c();BEGIN(REGEXPOK);return m(T_GE);}
 619 [<][=]                       {c();BEGIN(REGEXPOK);return m(T_LE);}
 620 [-][-]                       {c();BEGIN(DEFAULT);return m(T_MINUSMINUS);}
 621 [+][+]                       {c();BEGIN(DEFAULT);return m(T_PLUSPLUS);}
 622 [+][=]                       {c();BEGIN(REGEXPOK);return m(T_PLUSBY);}
 623 [\^][=]                      {c();BEGIN(REGEXPOK);return m(T_XORBY);}
 624 [-][=]                       {c();BEGIN(REGEXPOK);return m(T_MINUSBY);}
 625 [/][=]                       {c();BEGIN(REGEXPOK);return m(T_DIVBY);}
 626 [%][=]                       {c();BEGIN(REGEXPOK);return m(T_MODBY);}
 627 [*][=]                       {c();BEGIN(REGEXPOK);return m(T_MULBY);}
 628 [|][=]                       {c();BEGIN(REGEXPOK);return m(T_ORBY);}
 629 [&][=]                       {c();BEGIN(REGEXPOK);return m(T_ANDBY);}
 630 [>][>][=]                    {c();BEGIN(REGEXPOK);return m(T_SHRBY);}
 631 [<][<][=]                    {c();BEGIN(REGEXPOK);return m(T_SHLBY);}
 632 [>][>][>][=]                 {c();BEGIN(REGEXPOK);return m(T_USHRBY);}
 633 [<][<]                       {c();BEGIN(REGEXPOK);return m(T_SHL);}
 634 [>][>][>]                    {c();BEGIN(REGEXPOK);return m(T_USHR);}
 635 [>][>]                       {c();BEGIN(REGEXPOK);return m(T_SHR);}
 636 \.\.\.                       {c();BEGIN(REGEXPOK);return m(T_DOTDOTDOT);}
 637 \.\.                         {c();BEGIN(REGEXPOK);return m(T_DOTDOT);}
 638 \.                           {c();BEGIN(REGEXPOK);return m('.');}
 639 ::                           {c();BEGIN(REGEXPOK);return m(T_COLONCOLON);}
 640 :                            {c();BEGIN(REGEXPOK);return m(':');}
 641 instanceof                   {c();BEGIN(REGEXPOK);return m(KW_INSTANCEOF);}
 642 implements                   {c();BEGIN(REGEXPOK);return m(KW_IMPLEMENTS);}
 643 interface                    {c();BEGIN(DEFAULT);return m(KW_INTERFACE);}
 644 protected                    {c();BEGIN(DEFAULT);return m(KW_PROTECTED);}
 645 namespace                    {c();BEGIN(DEFAULT);return m(KW_NAMESPACE);}
 646 undefined                    {c();BEGIN(DEFAULT);return m(KW_UNDEFINED);}
 647 arguments                    {c();BEGIN(DEFAULT);return m(KW_ARGUMENTS);}
 648 continue                     {c();BEGIN(DEFAULT);return m(KW_CONTINUE);}
 649 override                     {c();BEGIN(DEFAULT);return m(KW_OVERRIDE);}
 650 internal                     {c();BEGIN(DEFAULT);return m(KW_INTERNAL);}
 651 function                     {c();BEGIN(DEFAULT);return m(KW_FUNCTION);}
 652 finally                      {c();BEGIN(DEFAULT);return m(KW_FINALLY);}
 653 default                      {c();BEGIN(DEFAULT);return m(KW_DEFAULT);}
 654 package                      {c();BEGIN(DEFAULT);return m(KW_PACKAGE);}
 655 private                      {c();BEGIN(DEFAULT);return m(KW_PRIVATE);}
 656 dynamic                      {c();BEGIN(DEFAULT);return m(KW_DYNAMIC);}
 657 extends                      {c();BEGIN(DEFAULT);return m(KW_EXTENDS);}
 658 delete                       {c();BEGIN(REGEXPOK);return m(KW_DELETE);}
 659 return                       {c();BEGIN(REGEXPOK);return m(KW_RETURN);}
 660 public                       {c();BEGIN(DEFAULT);return m(KW_PUBLIC);}
 661 native                       {c();BEGIN(DEFAULT);return m(KW_NATIVE);}
 662 static                       {c();BEGIN(DEFAULT);return m(KW_STATIC);}
 663 import                       {c();BEGIN(REGEXPOK);return m(KW_IMPORT);}
 664 typeof                       {c();BEGIN(REGEXPOK);return m(KW_TYPEOF);}
 665 throw                        {c();BEGIN(REGEXPOK);return m(KW_THROW);}
 666 class                        {c();BEGIN(DEFAULT);return m(KW_CLASS);}
 667 const                        {c();BEGIN(DEFAULT);return m(KW_CONST);}
 668 catch                        {c();BEGIN(DEFAULT);return m(KW_CATCH);}
 669 final                        {c();BEGIN(DEFAULT);return m(KW_FINAL);}
 670 false                        {c();BEGIN(DEFAULT);return m(KW_FALSE);}
 671 break                        {c();BEGIN(DEFAULT);return m(KW_BREAK);}
 672 super                        {c();BEGIN(DEFAULT);return m(KW_SUPER);}
 673 each                         {c();BEGIN(DEFAULT);return m(KW_EACH);}
 674 void                         {c();BEGIN(DEFAULT);return m(KW_VOID);}
 675 true                         {c();BEGIN(DEFAULT);return m(KW_TRUE);}
 676 null                         {c();BEGIN(DEFAULT);return m(KW_NULL);}
 677 else                         {c();BEGIN(DEFAULT);return m(KW_ELSE);}
 678 case                         {c();BEGIN(REGEXPOK);return m(KW_CASE);}
 679 with                         {c();BEGIN(REGEXPOK);return m(KW_WITH);}
 680 use                          {c();BEGIN(REGEXPOK);return m(KW_USE);}
 681 new                          {c();BEGIN(REGEXPOK);return m(KW_NEW);}
 682 get                          {c();BEGIN(DEFAULT);return m(KW_GET);}
 683 set                          {c();BEGIN(DEFAULT);return m(KW_SET);}
 684 var                          {c();BEGIN(DEFAULT);return m(KW_VAR);}
 685 try                          {c();BEGIN(DEFAULT);return m(KW_TRY);}
 686 is                           {c();BEGIN(REGEXPOK);return m(KW_IS) ;}
 687 in                           {c();BEGIN(REGEXPOK);return m(KW_IN) ;}
 688 if                           {c();BEGIN(DEFAULT);return m(KW_IF) ;}
 689 as                           {c();BEGIN(REGEXPOK);return m(KW_AS);}
 690 $?{NAME}                       {c();BEGIN(DEFAULT);return handleIdentifier();}
 691
 692 [\]\}*]                       {c();BEGIN(DEFAULT);return m(yytext[0]);}
 693 [+-\/^~@$!%&\(=\[|?:;,<>]   {c();BEGIN(REGEXPOK);return m(yytext[0]);}
 694 [\)\]]                           {c();BEGIN(DEFAULT);return m(yytext[0]);}
 695
 696 <DEFAULT,BEGINNING,REGEXPOK,XML,XMLTEXT>{
 697 .                            {tokenerror();}
 698 }
 699 <<EOF>>                      {l();
 700                               void*b = leave_file();
 701                               if (!b) {
 702                                  yyterminate();
 703                                  yy_delete_buffer(YY_CURRENT_BUFFER);
 704                                  return m(T_EOF);
 705                               } else {
 706                                   yy_delete_buffer(YY_CURRENT_BUFFER);
 707                                   yy_switch_to_buffer(b);
 708                               }
 709                              }
 710
 711 %%
 712
 713 int yywrap()
 714 {
 715     return 1;
 716 }
 717
 718 static int tokenerror()
 719 {
 720     char c1=yytext[0];
 721     char buf[128];
 722     buf[0] = yytext[0];
 723     int t;
 724     for(t=1;t<128;t++) {
 725         char c = buf[t]=input();
 726         if(c=='\n' || c==EOF)  {
 727             buf[t] = 0;
 728             break;
 729         }
 730     }
 731     if(c1>='0' && c1<='9')
 732         syntaxerror("syntax error: %s (identifiers must not start with a digit)");
 733     else
 734         syntaxerror("syntax error [%d]: %s", (yy_start-1)/2, buf);
 735     printf("\n");
 736     exit(1);
 737     yyterminate();
 738 }
 739
 740
 741 static char mbuf[256];
 742 char*token2string(enum yytokentype nr, YYSTYPE v)
 743 {
 744     if(nr==T_STRING) {
 745         char*s = malloc(v.str.len+10);
 746         strcpy(s, "<string>");
 747         memcpy(s+8, v.str.str, v.str.len);
 748         sprintf(s+8+v.str.len, " (%d bytes)", v.str.len);
 749         return s;
 750     }
 751     else if(nr==T_REGEXP) {
 752         char*s = malloc(strlen(v.regexp.pattern)+10);
 753         sprintf(s, "<regexp>%s", v.regexp.pattern);
 754         return s;
 755     }
 756     else if(nr==T_IDENTIFIER) {
 757         char*s = malloc(strlen(v.id)+10);
 758         sprintf(s, "<ID>%s", v.id);
 759         return s;
 760     }
 761     else if(nr==T_INT)     return "<int>";
 762     else if(nr==T_UINT)     return "<uint>";
 763     else if(nr==T_FLOAT)     return "<float>";
 764     else if(nr==T_EOF)        return "***END***";
 765     else if(nr==T_GE)         return ">=";
 766     else if(nr==T_LE)         return "<=";
 767     else if(nr==T_MINUSMINUS) return "--";
 768     else if(nr==T_PLUSPLUS)   return "++";
 769     else if(nr==KW_IMPLEMENTS) return "implements";
 770     else if(nr==KW_INTERFACE)  return "interface";
 771     else if(nr==KW_NAMESPACE)  return "namespace";
 772     else if(nr==KW_PROTECTED)  return "protected";
 773     else if(nr==KW_OVERRIDE)   return "override";
 774     else if(nr==KW_INTERNAL)   return "internal";
 775     else if(nr==KW_FUNCTION)   return "function";
 776     else if(nr==KW_PACKAGE)    return "package";
 777     else if(nr==KW_PRIVATE)    return "private";
 778     else if(nr==KW_BOOLEAN)    return "Boolean";
 779     else if(nr==KW_DYNAMIC)    return "dynamic";
 780     else if(nr==KW_EXTENDS)    return "extends";
 781     else if(nr==KW_PUBLIC)     return "public";
 782     else if(nr==KW_NATIVE)     return "native";
 783     else if(nr==KW_STATIC)     return "static";
 784     else if(nr==KW_IMPORT)     return "import";
 785     else if(nr==KW_NUMBER)     return "number";
 786     else if(nr==KW_CLASS)      return "class";
 787     else if(nr==KW_CONST)      return "const";
 788     else if(nr==KW_FINAL)      return "final";
 789     else if(nr==KW_FALSE)      return "False";
 790     else if(nr==KW_TRUE)       return "True";
 791     else if(nr==KW_UINT)       return "uint";
 792     else if(nr==KW_NULL)       return "null";
 793     else if(nr==KW_ELSE)       return "else";
 794     else if(nr==KW_USE)        return "use";
 795     else if(nr==KW_INT)        return "int";
 796     else if(nr==KW_NEW)        return "new";
 797     else if(nr==KW_GET)        return "get";
 798     else if(nr==KW_SET)        return "set";
 799     else if(nr==KW_VAR)        return "var";
 800     else if(nr==KW_IS)         return "is";
 801     else if(nr==KW_AS)         return "as";
 802     else {
 803         sprintf(mbuf, "%d", nr);
 804         return mbuf;
 805     }
 806 }
 807
 808 void tokenizer_begin_xml()
 809 {
 810     dbg("begin reading xml");
 811     BEGIN(XML);
 812 }
 813 void tokenizer_begin_xmltext()
 814 {
 815     dbg("begin reading xml text");
 816     BEGIN(XMLTEXT);
 817 }
 818 void tokenizer_end_xmltext()
 819 {
 820     dbg("end reading xml text");
 821     BEGIN(XML);
 822 }
 823 void tokenizer_end_xml()
 824 {
 825     dbg("end reading xml");
 826     BEGIN(DEFAULT);
 827 }
 828
 829 void initialize_scanner()
 830 {
 831     BEGIN(BEGINNING);
 832 }
 833
 834