lib/as3/tokenizer.lex

   1 /* tokenizer.lex
   2
   3    Routines for compiling Flash2 AVM2 ABC Actionscript
   4
   5    Extension module for the rfxswf library.
   6    Part of the swftools package.
   7
   8    Copyright (c) 2008 Matthias Kramm <kramm@quiss.org>
   9
  10    This program is free software; you can redistribute it and/or modify
  11    it under the terms of the GNU General Public License as published by
  12    the Free Software Foundation; either version 2 of the License, or
  13    (at your option) any later version.
  14
  15    This program is distributed in the hope that it will be useful,
  16    but WITHOUT ANY WARRANTY; without even the implied warranty of
  17    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18    GNU General Public License for more details.
  19
  20    You should have received a copy of the GNU General Public License
  21    along with this program; if not, write to the Free Software
  22    Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA */
  23 %{
  24
  25
  26 #include <string.h>
  27 #include <stdlib.h>
  28 #include <stdio.h>
  29 #include <stdarg.h>
  30 #include "../utf8.h"
  31 #include "tokenizer.h"
  32 #include "files.h"
  33
  34 int as3_pass = 0;
  35 int as3_verbosity = 1;
  36 unsigned int as3_tokencount = 0;
  37
  38 void as3_error(const char*format, ...)
  39 {
  40     char buf[1024];
  41     int l;
  42     va_list arglist;
  43     if(as3_verbosity<0)
  44         exit(1);
  45     va_start(arglist, format);
  46     vsprintf(buf, format, arglist);
  47     va_end(arglist);
  48     fprintf(stderr, "%s:%d:%d: error: %s\n", current_filename_short, current_line, current_column, buf);
  49     fflush(stderr);
  50     exit(1);
  51 }
  52 void as3_warning(const char*format, ...)
  53 {
  54     char buf[1024];
  55     int l;
  56     va_list arglist;
  57     if(as3_verbosity<1)
  58         return;
  59     va_start(arglist, format);
  60     vsprintf(buf, format, arglist);
  61     va_end(arglist);
  62     fprintf(stderr, "%s:%d:%d: warning: %s\n", current_filename_short, current_line, current_column, buf);
  63     fflush(stderr);
  64 }
  65 void as3_softwarning(const char*format, ...)
  66 {
  67     char buf[1024];
  68     int l;
  69     va_list arglist;
  70     if(as3_verbosity<2)
  71         return;
  72     va_start(arglist, format);
  73     vsprintf(buf, format, arglist);
  74     va_end(arglist);
  75     fprintf(stderr, "%s:%d:%d: warning: %s\n", current_filename_short, current_line, current_column, buf);
  76     fflush(stderr);
  77 }
  78 static void dbg(const char*format, ...)
  79 {
  80     char buf[1024];
  81     int l;
  82     va_list arglist;
  83     if(as3_verbosity<3)
  84         return;
  85     va_start(arglist, format);
  86     vsprintf(buf, format, arglist);
  87     va_end(arglist);
  88     l = strlen(buf);
  89     while(l && buf[l-1]=='\n') {
  90         buf[l-1] = 0;
  91         l--;
  92     }
  93     printf("(tokenizer) ");
  94     printf("%s\n", buf);
  95     fflush(stdout);
  96 }
  97
  98 #ifndef YY_CURRENT_BUFFER
  99 #define YY_CURRENT_BUFFER yy_current_buffer
 100 #endif
 101
 102 static void*as3_buffer=0;
 103 static int as3_buffer_pos=0;
 104 static int as3_buffer_len=0;
 105 void as3_file_input(FILE*fi)
 106 {
 107     as3_in = fi;
 108     as3_buffer = 0;
 109 }
 110 void as3_buffer_input(void*buffer, int len)
 111 {
 112     as3_buffer = buffer;
 113     as3_buffer_len = len;
 114     as3_buffer_pos = 0;
 115     as3_in = 0;
 116 }
 117
 118 #define YY_INPUT(buf,result,max_size) { \
 119   if(!as3_buffer) { \
 120       errno=0; \
 121       while((result = fread(buf, 1, max_size, as3_in))==0 && ferror(as3_in)) \
 122       { if(errno != EINTR) {YY_FATAL_ERROR("input in flex scanner failed"); break;} \
 123         errno=0; clearerr(as3_in); \
 124       } \
 125   } else { \
 126       int to_read = max_size; \
 127       if(to_read + as3_buffer_pos > as3_buffer_len) \
 128           to_read = as3_buffer_len - as3_buffer_pos; \
 129       memcpy(buf, as3_buffer+as3_buffer_pos, to_read); \
 130       as3_buffer_pos += to_read; \
 131       result=to_read; \
 132   } \
 133 }
 134
 135 void handleInclude(char*text, int len, char quotes)
 136 {
 137     char*filename = 0;
 138     if(quotes) {
 139         char*p1 = strchr(text, '"');
 140         char*p2 = strrchr(text, '"');
 141         if(!p1 || !p2 || p1==p2) {
 142             syntaxerror("Invalid include in line %d\n", current_line);
 143         }
 144         *p2 = 0;
 145         filename = strdup(p1+1);
 146     } else {
 147         int i1=0,i2=len;
 148         // find start
 149         while(!strchr(" \n\r\t", text[i1])) i1++;
 150         // strip
 151         while(strchr(" \n\r\t", text[i1])) i1++;
 152         while(strchr(" \n\r\t", text[i2-1])) i2--;
 153         if(i2!=len) text[i2]=0;
 154         filename = strdup(&text[i1]);
 155     }
 156
 157     char*fullfilename = find_file(filename);
 158     enter_file2(filename, fullfilename, YY_CURRENT_BUFFER);
 159     yyin = fopen(fullfilename, "rb");
 160     if (!yyin) {
 161         syntaxerror("Couldn't open include file \"%s\"\n", fullfilename);
 162     }
 163
 164     yy_switch_to_buffer(yy_create_buffer( yyin, YY_BUF_SIZE ) );
 165     //BEGIN(INITIAL); keep context
 166 }
 167
 168 static int do_unescape(const char*s, const char*end, char*n)
 169 {
 170     char*o = n;
 171     int len=0;
 172     while(s<end) {
 173         if(*s!='\\') {
 174             if(o) o[len] = *s;len++;
 175             s++;
 176             continue;
 177         }
 178         s++; //skip past '\'
 179         if(s==end) syntaxerror("invalid \\ at end of string");
 180
 181         /* handle the various line endings (mac, dos, unix) */
 182         if(*s=='\r') {
 183             s++;
 184             if(s==end) break;
 185             if(*s=='\n')
 186                 s++;
 187             continue;
 188         }
 189         if(*s=='\n')  {
 190             s++;
 191             continue;
 192         }
 193         switch(*s) {
 194             case '\\': if(o) o[len] = '\\';s++;len++; break;
 195             case '"': if(o) o[len] = '"';s++;len++; break;
 196             case '\'': if(o) o[len] = '\'';s++;len++; break;
 197             case 'b': if(o) o[len] = '\b';s++;len++; break;
 198             case 'f': if(o) o[len] = '\f';s++;len++; break;
 199             case 'n': if(o) o[len] = '\n';s++;len++; break;
 200             case 'r': if(o) o[len] = '\r';s++;len++; break;
 201             case 't': if(o) o[len] = '\t';s++;len++; break;
 202             case '0': case '1': case '2': case '3': case '4': case '5': case '6': case '7': {
 203                 unsigned int num=0;
 204                 int nr = 0;
 205                 while(strchr("01234567", *s) && nr<3 && s<end) {
 206                     num <<= 3;
 207                     num |= *s-'0';
 208                     nr++;
 209                     s++;
 210                 }
 211                 if(num>256)
 212                     syntaxerror("octal number out of range (0-255): %d", num);
 213                 if(o) o[len] = num;len++;
 214                 continue;
 215             }
 216             case 'x': case 'u': {
 217                 int max=2;
 218                 char bracket = 0;
 219                 char unicode = 0;
 220                 if(*s == 'u') {
 221                     max = 6;
 222                     unicode = 1;
 223                 }
 224                 s++;
 225                 if(s==end) syntaxerror("invalid \\u or \\x at end of string");
 226                 if(*s == '{')  {
 227                     s++;
 228                     if(s==end) syntaxerror("invalid \\u{ at end of string");
 229                     bracket=1;
 230                 }
 231                 unsigned int num=0;
 232                 int nr = 0;
 233                 while(strchr("0123456789abcdefABCDEF", *s) && (bracket || nr < max) && s<end) {
 234                     num <<= 4;
 235                     if(*s>='0' && *s<='9') num |= *s - '0';
 236                     if(*s>='a' && *s<='f') num |= *s - 'a' + 10;
 237                     if(*s>='A' && *s<='F') num |= *s - 'A' + 10;
 238                     nr++;
 239                     s++;
 240                 }
 241                 if(bracket) {
 242                     if(*s=='}' && s<end) {
 243                         s++;
 244                     } else {
 245                         syntaxerror("missing terminating '}'");
 246                     }
 247                 }
 248                 if(unicode) {
 249                     char*utf8 = getUTF8(num);
 250                     while(*utf8) {
 251                         if(o) o[len] = *utf8;utf8++;len++;
 252                     }
 253                 } else {
 254                     if(num>256)
 255                         syntaxerror("byte out of range (0-255): %d", num);
 256                     if(o) o[len] = num;len++;
 257                 }
 258                 break;
 259             }
 260             default:
 261                 syntaxerror("unknown escape sequence: \"\\%c\"", *s);
 262         }
 263     }
 264     if(o) o[len]=0;
 265     return len;
 266 }
 267
 268 static string_t string_unescape(const char*in, int l)
 269 {
 270     const char*s = in;
 271     const char*end = &in[l];
 272
 273     int len = do_unescape(s, end, 0);
 274     char*n = (char*)malloc(len+1);
 275     do_unescape(s, end, n);
 276     string_t out = string_new(n, len);
 277     return out;
 278 }
 279
 280 static void handleCData(char*s, int len)
 281 {
 282     a3_lval.str.str = s+9;    // <![CDATA[
 283     a3_lval.str.len = len-9-3;// ]]>
 284     a3_lval.str.str = strdup_n(a3_lval.str.str, a3_lval.str.len);
 285 }
 286
 287 static void handleString(char*s, int len)
 288 {
 289     if(as3_pass < 2) {
 290         // don't bother decoding strings in pass 1
 291         memset(&a3_lval, 0, sizeof(a3_lval));
 292         return;
 293     }
 294
 295     if(s[0]=='"') {
 296         if(s[len-1]!='"') syntaxerror("String doesn't end with '\"'");
 297         s++;len-=2;
 298     }
 299     else if(s[0]=='\'') {
 300         if(s[len-1]!='\'') syntaxerror("String doesn't end with '\"'");
 301         s++;len-=2;
 302     }
 303     else syntaxerror("String incorrectly terminated");
 304
 305
 306     a3_lval.str = string_unescape(s, len);
 307 }
 308
 309
 310 char start_of_expression;
 311
 312 static inline int handleIdentifier(int type)
 313 {
 314     char*s = malloc(yyleng+1);
 315     memcpy(s, yytext, yyleng);
 316     s[yyleng]=0;
 317     a3_lval.id = s;
 318     return type;
 319 }
 320
 321 static inline int m(int type)
 322 {
 323     a3_lval.token = type;
 324     return type;
 325 }
 326
 327
 328 static char numberbuf[64];
 329 static char*nrbuf()
 330 {
 331     if(yyleng>sizeof(numberbuf)-1)
 332         syntaxerror("decimal number overflow");
 333     char*s = numberbuf;
 334     memcpy(s, yytext, yyleng);
 335     s[yyleng]=0;
 336     return s;
 337 }
 338
 339 static inline int setint(int v)
 340 {
 341     a3_lval.number_int = v;
 342     if(v>-128)
 343         return T_BYTE;
 344     else if(v>=-32768)
 345         return T_SHORT;
 346     else
 347         return T_INT;
 348 }
 349 static inline int setuint(unsigned int v)
 350 {
 351     a3_lval.number_uint = v;
 352     if(v<128)
 353         return T_BYTE;
 354     else if(v<32768)
 355         return T_SHORT;
 356     else
 357         return T_UINT;
 358 }
 359 static inline int setfloat(double v)
 360 {
 361     a3_lval.number_float = v;
 362     return T_FLOAT;
 363 }
 364
 365 static inline int handlefloat()
 366 {
 367     char*s = nrbuf();
 368     a3_lval.number_float = atof(s);
 369     return T_FLOAT;
 370 }
 371
 372 static inline int handleint()
 373 {
 374     char*s = nrbuf();
 375     char l = (yytext[0]=='-');
 376
 377     char*max = l?"1073741824":"2147483647";
 378     if(yyleng-l>10) {
 379         as3_warning("integer overflow: %s (converted to Number)", s);
 380         return handlefloat();
 381     }
 382     if(yyleng-l==10) {
 383         int t;
 384         for(t=0;t<yyleng-l;t++) {
 385             if(yytext[l+t]>max[t]) {
 386                 as3_warning("integer overflow: %s (converted to Number)", s);
 387                 return handlefloat();
 388             }
 389             else if(yytext[l+t]<max[t])
 390                 break;
 391         }
 392     }
 393     if(yytext[0]=='-') {
 394         int v = atoi(s);
 395         return setint(v);
 396     } else {
 397         unsigned int v = 0;
 398         int t;
 399         for(t=0;t<yyleng;t++) {
 400             v*=10;
 401             v+=yytext[t]-'0';
 402         }
 403         return setuint(v);
 404     }
 405 }
 406
 407 static inline int handlehexfloat()
 408 {
 409     char l = (yytext[0]=='-')+2;
 410     double d=0;
 411     char dot=0;
 412     double base=1;
 413     int t;
 414     for(t=l;t<yyleng;t++) {
 415         char c = yytext[t];
 416         if(c=='.') {
 417             dot=1;
 418             continue;
 419         }
 420         if(!dot) {
 421             d*=16;
 422         } else {
 423             base*=1/16.0;
 424         }
 425         if(c>='0' && c<='9')
 426             d+=(c&15)*base;
 427         else if((c>='a' && c<='f') || (c>='A' && c<='F'))
 428             d+=((c&0x0f)+9)*base;
 429     }
 430     return setfloat(d);
 431 }
 432 static inline int handlehex()
 433 {
 434     char l = (yytext[0]=='-')+2;
 435     int len = yyleng;
 436
 437     if(len-l>8) {
 438         char*s = nrbuf();
 439         syntaxerror("integer overflow %s", s);
 440     }
 441
 442     int t;
 443     unsigned int v = 0;
 444     for(t=l;t<len;t++) {
 445         v<<=4;
 446         char c = yytext[t];
 447         if(c>='0' && c<='9')
 448             v|=(c&15);
 449         else if((c>='a' && c<='f') || (c>='A' && c<='F'))
 450             v|=(c&0x0f)+9;
 451     }
 452     if(l && v>1073741824) {
 453         char*s = nrbuf();
 454         as3_warning("signed integer overflow: %s (converted to Number)", s);
 455         return setfloat(v);
 456     }
 457     if(!l && v>2147483647) {
 458         char*s = nrbuf();
 459         as3_warning("unsigned integer overflow: %s (converted to Number)", s);
 460         return setfloat(v);
 461     }
 462
 463     if(l==3) {
 464         return setint(-(int)v);
 465     } else {
 466         return setuint(v);
 467     }
 468 }
 469
 470 void handleLabel(char*text, int len)
 471 {
 472     int t;
 473     for(t=len-1;t>=0;--t) {
 474         if(text[t]!=' ' &&
 475            text[t]!=':')
 476             break;
 477     }
 478     char*s = malloc(t+1);
 479     memcpy(s, yytext, t);
 480     s[t]=0;
 481     a3_lval.id = s;
 482 }
 483
 484 static int handleregexp()
 485 {
 486     char*s = malloc(yyleng);
 487     int len=yyleng-1;
 488     memcpy(s, yytext+1, len);
 489     s[len] = 0;
 490     int t;
 491     for(t=len;t>=0;--t) {
 492         if(s[t]=='/') {
 493             s[t] = 0;
 494             break;
 495         }
 496     }
 497     a3_lval.regexp.pattern = s;
 498     if(t==len) {
 499         a3_lval.regexp.options = 0;
 500     } else {
 501         a3_lval.regexp.options = s+t+1;
 502     }
 503     return T_REGEXP;
 504 }
 505
 506 void initialize_scanner();
 507 #define YY_USER_INIT initialize_scanner();
 508
 509 /* count the number of lines+columns consumed by this token */
 510 static inline void l() {
 511     int t;
 512     for(t=0;t<yyleng;t++) {
 513         if(yytext[t]=='\n') {
 514             current_line++;
 515             current_column=0;
 516         } else {
 517             current_column++;
 518         }
 519     }
 520 }
 521 /* count the number of columns consumed by this token */
 522 static inline void c() {
 523     current_column+=yyleng;
 524 }
 525
 526 //Boolean                      {c();return m(KW_BOOLEAN);}
 527 //int                          {c();return m(KW_INT);}
 528 //uint                         {c();return m(KW_UINT);}
 529 //Number                       {c();return m(KW_NUMBER);}
 530
 531 %}
 532
 533 %s REGEXPOK
 534 %s BEGINNING
 535
 536 NAME     [a-zA-Z_][a-zA-Z0-9_\\]*
 537 _        [^a-zA-Z0-9_\\]
 538
 539 HEXINT    0x[a-zA-Z0-9]+
 540 HEXFLOAT  0x[a-zA-Z0-9]*\.[a-zA-Z0-9]*
 541 INT       [0-9]+
 542 FLOAT     [0-9]+(\.[0-9]*)?|\.[0-9]+
 543
 544 HEXWITHSIGN [+-]?({HEXINT})
 545 HEXFLOATWITHSIGN [+-]?({HEXFLOAT})
 546 INTWITHSIGN [+-]?({INT})
 547 FLOATWITHSIGN [+-]?({FLOAT})
 548
 549 CDATA    <!\[CDATA\[([^]]|\][^]]|\]\][^>])*\]*\]\]\>
 550 STRING   ["](\\[\x00-\xff]|[^\\"\n])*["]|['](\\[\x00-\xff]|[^\\'\n])*[']
 551 S        [ \n\r\t]
 552 MULTILINE_COMMENT [/][*]+([*][^/]|[^/*]|[^*][/]|[\x00-\x1f])*[*]+[/]
 553 SINGLELINE_COMMENT \/\/[^\n]*\n
 554 REGEXP   [/]([^/\n]|\\[/])*[/][a-zA-Z]*
 555 %%
 556
 557
 558 {SINGLELINE_COMMENT}         {l(); /* single line comment */}
 559 {MULTILINE_COMMENT}          {l(); /* multi line comment */}
 560 [/][*]                       {syntaxerror("syntax error: unterminated comment", yytext);}
 561
 562 ^include{S}+{STRING}{S}*/\n    {l();handleInclude(yytext, yyleng, 1);}
 563 ^include{S}+[^" \t\r\n][\x20-\xff]*{S}*/\n    {l();handleInclude(yytext, yyleng, 0);}
 564 {STRING}                     {l(); BEGIN(INITIAL);handleString(yytext, yyleng);return T_STRING;}
 565 {CDATA}                      {l(); BEGIN(INITIAL);handleCData(yytext, yyleng);return T_STRING;}
 566
 567 <BEGINNING,REGEXPOK>{
 568 {REGEXP}                     {c(); BEGIN(INITIAL);return handleregexp();}
 569 {HEXWITHSIGN}                {c(); BEGIN(INITIAL);return handlehex();}
 570 {HEXFLOATWITHSIGN}           {c(); BEGIN(INITIAL);return handlehexfloat();}
 571 {INTWITHSIGN}                {c(); BEGIN(INITIAL);return handleint();}
 572 {FLOATWITHSIGN}              {c(); BEGIN(INITIAL);return handlefloat();}
 573 }
 574
 575 \xef\xbb\xbf                 {/* utf 8 bom */}
 576 {S}                          {l();}
 577
 578 {HEXINT}                     {c(); BEGIN(INITIAL);return handlehex();}
 579 {HEXFLOAT}                   {c(); BEGIN(INITIAL);return handlehexfloat();}
 580 {INT}                        {c(); BEGIN(INITIAL);return handleint();}
 581 {FLOAT}                      {c(); BEGIN(INITIAL);return handlefloat();}
 582
 583 3rr0r                        {/* for debugging: generates a tokenizer-level error */
 584                               syntaxerror("3rr0r");}
 585
 586 {NAME}{S}*:{S}*for/{_}        {l();handleLabel(yytext, yyleng-3);return T_FOR;}
 587 {NAME}{S}*:{S}*do/{_}         {l();handleLabel(yytext, yyleng-2);return T_DO;}
 588 {NAME}{S}*:{S}*while/{_}      {l();handleLabel(yytext, yyleng-5);return T_WHILE;}
 589 {NAME}{S}*:{S}*switch/{_}     {l();handleLabel(yytext, yyleng-6);return T_SWITCH;}
 590 for                          {c();a3_lval.id="";return T_FOR;}
 591 do                           {c();a3_lval.id="";return T_DO;}
 592 while                        {c();a3_lval.id="";return T_WHILE;}
 593 switch                       {c();a3_lval.id="";return T_SWITCH;}
 594
 595 [&][&]                       {c();BEGIN(REGEXPOK);return m(T_ANDAND);}
 596 [|][|]                       {c();BEGIN(REGEXPOK);return m(T_OROR);}
 597 [!][=]                       {c();BEGIN(REGEXPOK);return m(T_NE);}
 598 [!][=][=]                    {c();BEGIN(REGEXPOK);return m(T_NEE);}
 599 [=][=][=]                    {c();BEGIN(REGEXPOK);return m(T_EQEQEQ);}
 600 [=][=]                       {c();BEGIN(REGEXPOK);return m(T_EQEQ);}
 601 [>][=]                       {c();return m(T_GE);}
 602 [<][=]                       {c();return m(T_LE);}
 603 [-][-]                       {c();BEGIN(INITIAL);return m(T_MINUSMINUS);}
 604 [+][+]                       {c();BEGIN(INITIAL);return m(T_PLUSPLUS);}
 605 [+][=]                       {c();return m(T_PLUSBY);}
 606 [-][=]                       {c();return m(T_MINUSBY);}
 607 [/][=]                       {c();return m(T_DIVBY);}
 608 [%][=]                       {c();return m(T_MODBY);}
 609 [*][=]                       {c();return m(T_MULBY);}
 610 [|][=]                       {c();return m(T_ORBY);}
 611 [>][>][=]                    {c();return m(T_SHRBY);}
 612 [<][<][=]                    {c();return m(T_SHLBY);}
 613 [>][>][>][=]                 {c();return m(T_USHRBY);}
 614 [<][<]                       {c();return m(T_SHL);}
 615 [>][>][>]                    {c();return m(T_USHR);}
 616 [>][>]                       {c();return m(T_SHR);}
 617 \.\.\.                       {c();return m(T_DOTDOTDOT);}
 618 \.\.                         {c();return m(T_DOTDOT);}
 619 \.                           {c();return m('.');}
 620 ::                           {c();return m(T_COLONCOLON);}
 621 :                            {c();return m(':');}
 622 instanceof                   {c();return m(KW_INSTANCEOF);}
 623 implements                   {c();return m(KW_IMPLEMENTS);}
 624 interface                    {c();return m(KW_INTERFACE);}
 625 namespace                    {c();return m(KW_NAMESPACE);}
 626 protected                    {c();return m(KW_PROTECTED);}
 627 undefined                    {c();return m(KW_UNDEFINED);}
 628 continue                     {c();return m(KW_CONTINUE);}
 629 override                     {c();return m(KW_OVERRIDE);}
 630 internal                     {c();return m(KW_INTERNAL);}
 631 function                     {c();return m(KW_FUNCTION);}
 632 finally                      {c();return m(KW_FINALLY);}
 633 default                      {c();return m(KW_DEFAULT);}
 634 package                      {c();return m(KW_PACKAGE);}
 635 private                      {c();return m(KW_PRIVATE);}
 636 dynamic                      {c();return m(KW_DYNAMIC);}
 637 extends                      {c();return m(KW_EXTENDS);}
 638 delete                       {c();return m(KW_DELETE);}
 639 return                       {c();return m(KW_RETURN);}
 640 public                       {c();return m(KW_PUBLIC);}
 641 native                       {c();return m(KW_NATIVE);}
 642 static                       {c();return m(KW_STATIC);}
 643 import                       {c();return m(KW_IMPORT);}
 644 typeof                       {c();return m(KW_TYPEOF);}
 645 throw                        {c();return m(KW_THROW);}
 646 class                        {c();return m(KW_CLASS);}
 647 const                        {c();return m(KW_CONST);}
 648 catch                        {c();return m(KW_CATCH);}
 649 final                        {c();return m(KW_FINAL);}
 650 false                        {c();return m(KW_FALSE);}
 651 break                        {c();return m(KW_BREAK);}
 652 super                        {c();return m(KW_SUPER);}
 653 each                         {c();return m(KW_EACH);}
 654 void                         {c();return m(KW_VOID);}
 655 true                         {c();return m(KW_TRUE);}
 656 null                         {c();return m(KW_NULL);}
 657 else                         {c();return m(KW_ELSE);}
 658 case                         {c();return m(KW_CASE);}
 659 with                         {c();return m(KW_WITH);}
 660 use                          {c();return m(KW_USE);}
 661 new                          {c();return m(KW_NEW);}
 662 get                          {c();return m(KW_GET);}
 663 set                          {c();return m(KW_SET);}
 664 var                          {c();return m(KW_VAR);}
 665 try                          {c();return m(KW_TRY);}
 666 is                           {c();return m(KW_IS) ;}
 667 in                           {c();return m(KW_IN) ;}
 668 if                           {c();return m(KW_IF) ;}
 669 as                           {c();return m(KW_AS);}
 670 {NAME}                       {c();BEGIN(INITIAL);return handleIdentifier(T_IDENTIFIER);}
 671
 672 [+-\/*^~@$!%&\(=\[\]\{\}|?:;,<>] {c();BEGIN(REGEXPOK);return m(yytext[0]);}
 673 [\)\]]                           {c();BEGIN(INITIAL);return m(yytext[0]);}
 674
 675 .                            {/* ERROR */
 676                               char c1=yytext[0];
 677                               char buf[128];
 678                               buf[0] = yytext[0];
 679                               int t;
 680                               for(t=1;t<128;t++) {
 681                                   char c = buf[t]=input();
 682                                   if(c=='\n' || c==EOF)  {
 683                                       buf[t] = 0;
 684                                       break;
 685                                   }
 686                               }
 687                               if(c1>='0' && c1<='9')
 688                                   syntaxerror("syntax error: %s (identifiers must not start with a digit)");
 689                               else
 690                                   syntaxerror("syntax error: %s", buf);
 691                               printf("\n");
 692                               exit(1);
 693                               yyterminate();
 694                              }
 695 <<EOF>>                      {l();
 696                               void*b = leave_file();
 697                               if (!b) {
 698                                  yyterminate();
 699                                  yy_delete_buffer(YY_CURRENT_BUFFER);
 700                                  return m(T_EOF);
 701                               } else {
 702                                   yy_delete_buffer(YY_CURRENT_BUFFER);
 703                                   yy_switch_to_buffer(b);
 704                               }
 705                              }
 706
 707 %%
 708
 709 int yywrap()
 710 {
 711     return 1;
 712 }
 713
 714 static char mbuf[256];
 715 char*token2string(enum yytokentype nr, YYSTYPE v)
 716 {
 717     if(nr==T_STRING)     return "<string>";
 718     else if(nr==T_INT)     return "<int>";
 719     else if(nr==T_UINT)     return "<uint>";
 720     else if(nr==T_BYTE)     return "<byte>";
 721     else if(nr==T_FLOAT)     return "<float>";
 722     else if(nr==T_REGEXP)     return "REGEXP";
 723     else if(nr==T_EOF)        return "***END***";
 724     else if(nr==T_GE)         return ">=";
 725     else if(nr==T_LE)         return "<=";
 726     else if(nr==T_MINUSMINUS) return "--";
 727     else if(nr==T_PLUSPLUS)   return "++";
 728     else if(nr==KW_IMPLEMENTS) return "implements";
 729     else if(nr==KW_INTERFACE)  return "interface";
 730     else if(nr==KW_NAMESPACE)  return "namespace";
 731     else if(nr==KW_PROTECTED)  return "protected";
 732     else if(nr==KW_OVERRIDE)   return "override";
 733     else if(nr==KW_INTERNAL)   return "internal";
 734     else if(nr==KW_FUNCTION)   return "function";
 735     else if(nr==KW_PACKAGE)    return "package";
 736     else if(nr==KW_PRIVATE)    return "private";
 737     else if(nr==KW_BOOLEAN)    return "Boolean";
 738     else if(nr==KW_DYNAMIC)    return "dynamic";
 739     else if(nr==KW_EXTENDS)    return "extends";
 740     else if(nr==KW_PUBLIC)     return "public";
 741     else if(nr==KW_NATIVE)     return "native";
 742     else if(nr==KW_STATIC)     return "static";
 743     else if(nr==KW_IMPORT)     return "import";
 744     else if(nr==KW_NUMBER)     return "number";
 745     else if(nr==KW_CLASS)      return "class";
 746     else if(nr==KW_CONST)      return "const";
 747     else if(nr==KW_FINAL)      return "final";
 748     else if(nr==KW_FALSE)      return "False";
 749     else if(nr==KW_TRUE)       return "True";
 750     else if(nr==KW_UINT)       return "uint";
 751     else if(nr==KW_NULL)       return "null";
 752     else if(nr==KW_ELSE)       return "else";
 753     else if(nr==KW_USE)        return "use";
 754     else if(nr==KW_INT)        return "int";
 755     else if(nr==KW_NEW)        return "new";
 756     else if(nr==KW_GET)        return "get";
 757     else if(nr==KW_SET)        return "set";
 758     else if(nr==KW_VAR)        return "var";
 759     else if(nr==KW_IS)         return "is";
 760     else if(nr==KW_AS)         return "as";
 761     else if(nr==T_IDENTIFIER)  return "ID";
 762     else {
 763         sprintf(mbuf, "%d", nr);
 764         return mbuf;
 765     }
 766 }
 767
 768 void initialize_scanner()
 769 {
 770     BEGIN(BEGINNING);
 771 }
 772
 773